Status quo w. fixed attribute levels

This forum is for posts that specifically focus on Ngene.

Moderators: Andrew Collins, Michiel Bliemer, johnr

Re: Status quo w. fixed attribute levels

Postby bassieeco » Mon Aug 23, 2021 5:37 pm

Dear Ngene users,

I am working on a design for a DCE with three alternatives (two plus one status quo ), 4 attributes, with 3, 4, 4 and 8 levels. The attribute level of one of the attributes (i.e. PDRR_SR) only appears in the SQ options. This will result in perfect correlation with the SQ alternative

Here is my syntax

design
;alts= alt1*,alt2*,SQ

;rows=48
;block=6

;eff = (mnl,d,mean)
;alg=mfederov(candidates = 5000)

;require:
alt1.EO > 0,
alt2.EO > 0,

alt1.PDRR_SR>0,
alt2.PDRR_SR>0,

alt1.cost > 0,
alt2.cost > 0,
alt1.cost <> alt2.cost,

SQ.WLHQ = 0,
SQ.PDRR_SR = 0,
SQ.EO = 0,
SQ.cost = 0

;model:
U(alt1) =b1.effects[(n,0,0)|(n,0,0)]*WLHQ[2,1,0]
+b2.effects[(n,0,0)|(n,0,0)|(n,0,0)]*PDRR_SR[3,2,1,0]
+b3[(n,0,0)]*EO[0,150,300,400]
+b4[(n,-0.0001,0)]*cost[0,20,30,40,50,60,70,80]/
U(alt2) =b1*WLHQ
+b2*PDRR_SR
+b3*EO
+b4*cost/
U(SQ) = b1*WLHQ
+b2*PDRR_SR
+b3*EO
+b4*cost$

The paper by Cooper et.al used a hybrid coding approach to solve the problem of correlation between the base variable and SQ alternatives. Cooper, B., Rose, J.M. and Crase, L. (2012) Does anybody like water restrictions? Some observations in Australian urban communities, Australian Journal of Agricultural and Resource Economics, 56(1), 61-51.
How to code a hybrid approach using Ngene? Any suggestions, please
Thank you
Bassie
bassieeco
 
Posts: 4
Joined: Wed Aug 18, 2021 11:28 am

Re: Status quo w. fixed attribute levels

Postby Michiel Bliemer » Tue Aug 24, 2021 10:48 am

Two things to mention:

1. You are using zero priors for all coefficients except the cost coefficient. Therefore, dominance checks cannot be performed since all choice tasks will have a dominant alternative if costs are different. You either need to provide the sign of the priors for all or most coefficients, or you need to use zero for all of them. The syntax below works fine.

2. There is no issue with perfect correlation in your case, only when you try to estimate an additional constant for the status quo alternative you will run into problems since this constant will be confounded with the fixed base level. So you do not need to use the trick in Cooper et al. If Ngene provides a finite D-error (which it does in this case) you will be able to estimate the model and there is no confounding effect. When Ngene produces an Undefined or infinite D-error then there is an identification issue.

Code: Select all
design
;alts = alt1*,alt2*,SQ

;rows = 48
;block = 6

;eff = (mnl,d,mean)
;alg = mfederov

;require:
alt1.EO > 0,
alt2.EO > 0,

alt1.PDRR_SR>0,
alt2.PDRR_SR>0,

alt1.cost > 0,
alt2.cost > 0,
alt1.cost <> alt2.cost,

SQ.WLHQ = 0,
SQ.PDRR_SR = 0,
SQ.EO = 0,
SQ.cost = 0

;model:
U(alt1) = b1.effects[(n,0,0)|(n,0,0)]         * WLHQ[2,1,0]
        + b2.effects[(n,0,0)|(n,0,0)|(n,0,0)] * PDRR_SR[3,2,1,0]
        + b3[(n,0,0)]                         * EO[0,150,300,400]
        + b4[(n,0,0)]                         * cost[0,20,30,40,50,60,70,80]
        /
U(alt2) = b1                                  * WLHQ
        + b2                                  * PDRR_SR
        + b3                                  * EO
        + b4                                  * cost
        /
U(SQ)   = b1                                  * WLHQ
        + b2                                  * PDRR_SR
        + b3                                  * EO
        + b4                                  * cost
$


Michiel
Michiel Bliemer
 
Posts: 1705
Joined: Tue Mar 31, 2009 4:13 pm

Re: Status quo w. fixed attribute levels

Postby bassieeco » Tue Aug 24, 2021 12:11 pm

Thank you very much for your help!
Bassie
bassieeco
 
Posts: 4
Joined: Wed Aug 18, 2021 11:28 am

Re: Status quo w. fixed attribute levels

Postby Michiel Bliemer » Tue Aug 24, 2021 12:27 pm

Note that the modified Federov algorithm does not impose attribute level balance, so for attributes EO and cost the design will likely mostly have extreme levels and not use the inner levels. In that case, you can include attribute level constraints. For example, for attribute EO with 4 levels, you would have perfect attribute level balance if each level appears 12 times. You could impose constraints by using EO[0,150,300,400](10-14,10-14,10-14,10-14) that requires that each level appears between 10 and 14 times within the design. You will need to check with your constraints whether this is achieveable for all alternatives. Instead of imposing such hard constraints, you can also impose a soft constraint by using something like ;eff = (mnl,d) + 2 * (imbalance).

Finally, you are asking for Bayesian efficient design, but you provide zero priors for all of them. So you should either use ;eff = (mnl,d,fixed) or you should replace (n,0,0) with 0.

Michiel
Michiel Bliemer
 
Posts: 1705
Joined: Tue Mar 31, 2009 4:13 pm

Previous

Return to Choice experiments - Ngene

Who is online

Users browsing this forum: No registered users and 8 guests

cron