Interactions and constraints

[saro]

Hi,

I am trying to produce a design that has a number of constraints placed on it and as such I'm finding it a bit hard to produce a model that works. I have two questions really. The first is how the model is affected by using restrictions on it to determine the levels in the design (Model 1 below) as opposed to setting different levels between alternatives in the utility function (Model 2). The second question is around generating a model in which I can include interactions. Both models below generate a design I think I am happy with when I keep the model simple, however when I start adding in complexities (in this case interactions) the models can no longer generate a design. Do you have any suggestions as to how I can add in interactions and still generate a sensible model?

Model 1
design
;alts = PlanA*, PlanB*
;rows = 16
;eff = (mnl,d)
;alg = mfederov(candidates=10000000)
;require:
PlanA.Att5 = 0,
PlanB.Att1 + PlanB.Att2 + PlanB.Att3 + PlanB.Att4 = 0
;reject:
PlanB.Att5 = 0
;model:
U(PlanA) = b1 * Att1[0,5,10,15] + b2 * Att2[0,5,10,15] + b3 * Att3[0,5,10,15] + b4 * Att4[0,5,10,15] + b5 * Att5[0,10,15,25] + i1 * Att1 * Att5 + i2 * Att1 * Att5 + i3 * Att3 * Att5 + i4 * Att4 * Att5/
U(PlanB) = b1 * Att1 + b2 * Att2 + b3 * Att3 + b4 * Att4 + b5 * Att5 + i1 * Att1 * Att5 + i2 * Att1 * Att5 + i3 * Att3 * Att5 + i4 * Att4 * Att5
$

Model 2
design
;alts = PlanA*, PlanB*
;rows = 16
;eff = (mnl,d)
;model:
U(PlanA) = b1 * Att1[0,5,10,15] + b2 * Att2[0,5,10,15] + b3 * Att3[0,5,10,15] + b4 * Att4[0,5,10,15] + b5 * Att5[0]+ i1 * Att1 * Att5 + i2 * Att1 * Att5 + i3 * Att3 * Att5 + i4 * Att4 * Att5 /
U(PlanB) = b1 * Att1b[0] + b2 * Att2b[0] + b3 * Att3b[0] + b4 * Att4b[0] + b5 * Att5b[10,15,25] + i1 * Att1b * Att5b + i2 * Att2b * Att5b + i3 * Att3b * Att5b + i4 * Att4b * Att5b
$

Thanks...

[Michiel Bliemer]

I am trying to understand what you are doing. First two questions from my side:

I understand that you would like to impose the following constraints:
require:
PlanA.Att5 = 0,
PlanB.Att1 + PlanB.Att2 + PlanB.Att3 + PlanB.Att4 = 0,
PlanB.Att5 > 0

Correct? In that case, I do not understand the second constraint that they need to sum to zero. The only choice task that satisfies this constraint is that all levels are zero. There is no design that can satisfy these constraints, or do you want to create a status quo with all zeros?

Further, I do not understand the * behind the alternatives, if you specify all zero priors then Ngene cannot remove dominant alternatives, so the * is obsolete.

[Michiel Bliemer]

Also, I do not understand the interactions in Model 2, if att1b, att2b, att3b, and att4b are all set to zero, then all interaction effects will be zero so the interaction coefficients cannot be estimated.

[saro]

Hi Michael,

Thanks for your response. As you can tell I'm new to choice experiment design. That's correct in that the second constraint was the simplest way I could think to satisfy the constraint that all levels are zero for those 4 attributes. I am trying to create a design where respondents are asked to choose between one alternative where the attributes vary or one alternative where the willingness to pay to varies, i.e would the participant take the package or the cash? In this sense alternative 1 represents the package of attributes (1-4) with varying attributes and alternative 2 represents the WTP (attribute 5) which can vary, but the other attributes are held constant and zero. I hope this makes sense.

With regards to the *, I had the impression that by setting the alternatives as unlabelled this also removed duplicate alternatives, however this is obviously my misunderstanding. Thank you for clarifying this.

Lastly, yes you are correct with regards to the interactions with Model 2.

[Michiel Bliemer]

The following two syntax files work:

design
;alts = PlanA, PlanB
;rows = 16
;alg = mfederov(candidates = 200)
;eff = (mnl,d)
;require:
PlanB.Att1 = 0,
PlanB.Att2 = 0,
PlanB.Att3 = 0,
PlanB.Att4 = 0,
PlanA.Att5 = 0,
PlanB.Att5 > 0
;model:
U(PlanA) = b1 * Att1[0,5,10,15] + b2 * Att2[0,5,10,15] + b3 * Att3[0,5,10,15] + b4 * Att4[0,5,10,15] + b5 * Att5[0,10,15,25] /
U(PlanB) = b1 * Att1 + b2 * Att2 + b3 * Att3 + b4 * Att4 + b5 * Att5
$

design
;alts = PlanA, PlanB
;rows = 16
;eff = (mnl,d)
;model:
U(PlanA) = b1 * Att1[0,5,10,15] + b2 * Att2[0,5,10,15] + b3 * Att3[0,5,10,15] + b4 * Att4[0,5,10,15] /
U(PlanB) = b5 * Att5[10,15,25]
$

Both utility specifications are identical. In the first syntax the modified federov algorithm is used (which often finds more efficient designs, but may not satisfy attribute level balance), while in the second the swapping algorithm is used (which finds somewhat less efficient designs, but maintains attribute level balance).

You are correct that the * may also avoid duplicate alternatives in an unlabelled experiment, but since you set PlanA.Att5 = 0 and PlanB.Att5 > 0, overlap cannot occur, so you can omit the * in this case.

Michiel

[saro]

Thanks Michael,

This code works well and additionally works when I start adding in added complexities (e.g. priors). When I set a much larger number of rows it is likely that attribute level balance is achieved to some extent in the first design, so I will give this a go too.

Thanks,