Designs within designs question

This forum is for posts that specifically focus on Ngene.

Moderators: Andrew Collins, Michiel Bliemer, johnr

Designs within designs question

Postby Anat Tchetchik » Mon Sep 19, 2016 11:21 am

Hi all,
I have a labelled design, with 3 alts. and an 'optout' option.
The attribute 'risk' is being fixed in all alts.. Yet this prior has a poitive value for all three alt. (the riskier the climate change the more utility one has to participate a coslty effort) Yet, for the 'optout' I would still like to keep the "Designs within design" option for 'risk' but to assign a negative value either the prior 'b3' or to it's level 'risk' , since for non-participation one incur negative utility the higher the risk is.
I tried to assign a minus, (highlighted in the last row.) But this is not a valid specification. Is there to design the experiment I'm looking for?
Thanks, Anat.
Code: Select all
Design
;alts = device, garden, money, optout
;rows = 32
;block=8
;eff = (mnl,d)
;model:
U(device) =b1[n,0.21,0.0627]+ b2[0.4]*participation[2,5,9] + b3[0.241]* risk[1,2.5,4]+b4[-0.154]*working[2,3,4]/
U(garden) =c1[n,0.18,0.0643]+ b2 * participation+ b3* [[b]risk[/b]]+b4*working[2,3,4]/
U(money) = d1[n,0.19,0.0783]+ b2 * participation+ b3* [[b]risk[/b]]+b5[-0.7]*cost[2,3,4]/
U(optout)= b3* risk[-([b]risk[/b])]$

Anat Tchetchik
 
Posts: 61
Joined: Fri Sep 16, 2011 3:58 am
Location: ISRAEL

Re: Designs within designs question

Postby Michiel Bliemer » Mon Sep 19, 2016 4:20 pm

The following syntax will work, but this leaves out the risk attribute in the optout alternative:

Design
;alts = device, garden, money, optout
;rows = 32
;block=8
;eff = (mnl,d)
;model:
U(device) =b1[n,0.21,0.0627]+ b2[0.4]*participation[2,5,9] + b3[0.241]* risk[1,2.5,4]+b4[-0.154]*working[2,3,4]/
U(garden) =c1[n,0.18,0.0643]+ b2 * participation+ b3* risk[risk]+b4*working[2,3,4]/
U(money) = d1[n,0.19,0.0783]+ b2 * participation+ b3* risk[risk]+b5[-0.7]*cost[2,3,4]
$

You cannot use risk[-risk], only risk[risk] is supported. You could set b3 to minus b2 for the same effect, that is,

Design
;alts = device, garden, money, optout
;rows = 32
;block=8
;eff = (mnl,d)
;model:
U(device) =b1[n,0.21,0.0627]+ b2[0.4]*participation[2,5,9] + b3[0.241]* risk[1,2.5,4]+b4[-0.154]*working[2,3,4]/
U(garden) =c1[n,0.18,0.0643]+ b2 * participation+ b3* risk[risk]+b4*working[2,3,4]/
U(money) = d1[n,0.19,0.0783]+ b2 * participation+ b3* risk[risk]+b5[-0.7]*cost[2,3,4] /
U(optout) = b4[-0.241]*risk[risk]
$

This does however assume that you are estimating a fourth parameter (b4), but I do not see how you could do this otherwise in Ngene.

The best thing to do is to rewrite the utility functions by adding b3*risk to each alternative, which gives:

Design
;alts = device, garden, money, optout
;rows = 32
;block=8
;eff = (mnl,d)
;model:
U(device) =b1[n,0.21,0.0627]+ b2[0.4]*participation[2,5,9] + b3[0.482]* risk[1,2.5,4]+b4[-0.154]*working[2,3,4]/
U(garden) =c1[n,0.18,0.0643]+ b2 * participation+ b3* risk[risk]+b4*working[2,3,4]/
U(money) = d1[n,0.19,0.0783]+ b2 * participation+ b3* risk[risk]+b5[-0.7]*cost[2,3,4]
$

Notice that U(optout) = 0 in this case, and that b3 is now double the value, namely 0.482.
Michiel Bliemer
 
Posts: 1705
Joined: Tue Mar 31, 2009 4:13 pm

Re: Designs within designs question

Postby Anat Tchetchik » Mon Sep 19, 2016 10:24 pm

Thank you Michiel, that was very helpful!
Anat Tchetchik
 
Posts: 61
Joined: Fri Sep 16, 2011 3:58 am
Location: ISRAEL


Return to Choice experiments - Ngene

Who is online

Users browsing this forum: No registered users and 12 guests

cron