No design generated when adding one Bayesian parameter

[Anat Tchetchik]

Dear all,

May be this expected given the number of parameters included, yet to be sure, before I quit the idea of using Bayesian design..
This design is working well:

Code: Select all

Design
;alts = device, garden, money, optout
;rows = 24
;block=6
;eff = (mnl,d)
;rdraws=gauss(2)
;model:
U(device) =b1[n,0.21,0.062]+ b2[n,0.4,0.2]*participation[1,2,3] + b3[n,0.48,0.19]* risk[1,2,3]+b4[n,-0.154,0.11]*working[1,2,3]/
U(garden) =c1[n,0.188,0.064]+ b2 * participation+ b3* risk[risk]+b4*working/
U(money) = d1[n,0.194,0.078]+ b2 * participation+ b3* risk[risk]+b5[n,-0.7,0.1]*cost[1,2,3] /
U(optout)= b2 *participation$


Yet, when I add a Bayesian distribution to only one ASC, b1, as in the example below, no design is being generated.. (and ideally I would like to assign Bayesian distribution to my three ASC). is this merely impossible given the amount of parameters I have? or have I done something wrong in the syntax below?

Code: Select all

Design
;alts = device, garden, money, optout
;rows = 24
;block=6
;eff = (rp,d)
;rdraws=halton(250)
;bdraws=halton(250)
;rep = 500
;model:
U(device) =b1[n,(n,0.21,0.0627),(u,0.114,0.227)]+ b2[n,0.4,0.2]*participation[1,2,3] + b3[n,0.48,0.19]* risk[1,2,3]+b4[n,-0.154,0.11]*working[1,2,3]/
U(garden) =c1[n,0.188,0.064]+ b2 * participation+ b3* risk[risk]+b4*working/
U(money) = d1[n,0.194,0.078]+ b2 * participation+ b3* risk[risk]+b5[n,-0.7,0.1]*cost[1,2,3] /
U(optout)= b2 *participation$


Thanks!
Anat

[Michiel Bliemer]

Note that it has nothing to do with Bayesian priors, it has to do with the fact that you are trying to estimate a random parameter model in which you have 3 normally distributed constants. Constants are always difficult to estimate, and in this case you want to estimate 3 constants described by distributions, which is quite challenging. If you make the constants fixed instead of random, it should work. Note that you also may want to change rp to rppanel, since rp is not the right model for stated choice experiments. But it is very hard to optimise for rppanel, so it is suggested that you optimise for mnl and evaluate the design under rppanel.

Design
;alts = device, garden, money, optout
;rows = 24
;block=6
;eff = (rp,d)
;rdraws=halton(250)
;model:
U(device) =b1[0.21]+ b2[n,0.4,0.2]*participation[1,2,3] + b3[n,0.48,0.19]* risk[1,2,3]+b4[n,-0.154,0.11]*working[1,2,3]/
U(garden) =c1[0.188]+ b2 * participation+ b3* risk[risk]+b4*working/
U(money) = d1[0.194]+ b2 * participation+ b3* risk[risk]+b5[n,-0.7,0.1]*cost[1,2,3] /
U(optout)= b2 *participation$

[Anat Tchetchik]

Thank you Michiel,
I'm sorry for the confusion regarding the title of the post (can I still change the subject of the post?).
The design (below) that works well ia already Bayesian efficient.. note, that it did work with 3 normally distributed constants.. which is great!
What did not work is when i added Bayesian parameter distribution for the error component of the ASC b1 (or the other constants).
that is I add the RHS:

Code: Select all

=b1[n,(n,0.21,0.0627),(u,0.114,0.227)]

From your reply I understand that it is expected when it comes to constants. Just one small question, when I includes the distribution for the error component, I needed to add the ;bdraws specification. I guess that is the source of my confusion. What is the difference between rdraws and bdraws? I could not find it in the manual.

Code: Select all

Design
;alts = device, garden, money, optout
;rows = 16
;eff = (mnl,d)
;rdraws=halton(250)
;model:
U(device) =b1[n,0.21,0.0627]+ b2[n,0.4,0.2]*participation[1,2,3] + b3[n,0.48,0.19]* risk[1,2,3]+b4[n,-0.154,0.11]*working[1,2,3]/
U(garden) =c1[n,0.188,0.064]+ b2 * participation+ b3* risk[risk]+b4*working/
U(money) = d1[n,0.194,0.078]+ b2 * participation+ b3* risk[risk]+b5[n,-0.7,0.1]*cost[1,2,3] /
U(optout)= b2 *participation$


Thanks again for you time and patient!

[Michiel Bliemer]

In theory it is possible to estimate error component (normally distributed constants) and to use Bayesian priors, but when I ran your code I could observe that the standard deviations of the constants were very difficult to estimate. You can check this by running the syntax, stopping the syntax and then Ngene produces its last design it evaluated. When you inspect it, you will see that the Covariance matrix has very large values for the mean and standard deviation of the constants. This is why it generates an 'undefined' D-error, since it seems almost impossible to estimate the standard deviations.

;rdraws is for Random parameters, e.g. b1[n,0,1]
;bdraws is for Bayesian priors, e.g. b1[(n,0,1)]

You need to use both if you want both random parameters and Bayesian priors, e.g. b1[n,(n,1,0.2),(u,0.1,0.2)]
In case you want to rppanel (acounting for the fact that respondents face multiple choice tasks), you also need to set ;rep
If you do not set any of them, Ngene simply uses some default settings (a low number of Halton draws).

Michiel

[Anat Tchetchik]

Thanks you very much. I understand now. I guess I'll resort to your original suggestion with fixed priors for the constants. Many thanks again!