status quo option

This forum is for posts that specifically focus on Ngene.

Moderators: Andrew Collins, Michiel Bliemer, johnr

status quo option

Postby amz » Wed Jul 05, 2017 8:49 pm

Hi guys, I want to get a design with a status quo option.
Sq is going to be the same for all respondents and I am struggling with the coding of the dummy variables in the status quo alternative.
I could not leave the weighting parameter in the Sq option as A2.dummy because it was not accepted, so had to change both the name of weighting parameter and the attribute. I put a prior value there then, but I guess that should refer to the particular level, and therefore be different from the one in the other alternatives? I tried both option
In any case I cannot obtain a design. I do when I only consider the non-dummy attributes in the sq.
Is it a coding problem or something else? See my synthax below
Any suggestion much appreciated. Thanks and all the best
Alberto

Design;
;alts= alt1,alt2,alt3
;rows=24
;block=3
;eff= (mnl,d)
;model:
U(alt1)=A1[0.0001]* Ground Cover [10,25,50]+ A2.dummy [0.0001]* Flower [0,1] +
A3[0.0001]*Tree Canopy Cover [10,25,50]+ A4.dummy[0.0001|0.0001]*Road Island [0,1,2]
+ A5.dummy[0.0001]*Bicycle Lane [0,1]+A6.dummy[0.0001]*Pedestrian Walkway[0,1]+A7[0.0001]*car lanes [4,5,6]
+A8[-0.0001]*tax[500,1000,2000,3000,4000,5000]/
U(alt2)=A1* Ground Cover [10,25,50]+ A2.dummy* Flower [0,1] +
A3*Tree Canopy Cover [10,25,50]+ A4.dummy*Road Island [0,1,2]
+ A5.dummy*Bicycle Lane [0,1]+A6.dummy*Pedestrian Walkway[0,1]+A7*car lanes [4,5,6]
+A8*tax[500,1000,2000,3000,4000,5000]/
U(alt3)=A1* Ground Cover Sq [10]+ A2sq[0.0001]* Flower Sq [0] +
A3*Tree Canopy Cover Sq [25]+ A4sq[0.0001]*Road Island Sq [0]
+ A5sq [0.0001]*Bicycle Lane Sq [0]+A6sq [0.0001]*Pedestrian Walkway Sq[0]+A7*car lanes Sq [4]
+A8*tax sq[0]$
amz
 
Posts: 2
Joined: Tue Jul 04, 2017 8:44 pm

Re: status quo option

Postby Michiel Bliemer » Fri Jul 07, 2017 6:06 am

You can use constraints to fix the status quo attributes.

I believe that the syntax below does what you are looking for. I am using 250 candidate choice tasks, and Ngene will select the best 24. Note that increasing this number makes it more difficult for Ngene to find feasible choice tasks, but I believe that that there is enough variation in the 250 candidate choice tasks in order to find an efficient design.

Code: Select all
Design;
;alts = alt1, alt2, sq
;rows = 24
;block = 3
;eff = (mnl,d)

;alg = mfederov(candidates = 250)

;require:
alt1.tax > 0,
alt2.tax > 0,
sq.Ground_Cover = 10 and sq.Flower = 0 and sq.Tree_Canopy_Cover = 25 and sq.Road_Island = 0 and sq.Bicycle_Lane = 0 and sq.Pedestrian_Walkway = 0 and sq.car_lanes = 4 and sq.tax = 0

;model:
U(alt1)= A1[0.0001] * Ground_Cover[10,25,50] +
         A2.dummy[0.0001] * Flower[0,1] +
         A3[0.0001] * Tree_Canopy_Cover[10,25,50] +
         A4.dummy[0.0001|0.0001] * Road_Island[0,1,2] +
         A5.dummy[0.0001] * Bicycle_Lane[0,1] +
         A6.dummy[0.0001] * Pedestrian_Walkway[0,1] +
         A7[0.0001] * car_lanes[4,5,6] +
         A8[-0.0001] * tax[0,500,1000,2000,3000,4000,5000] /

U(alt2)= A1 * Ground_Cover +
         A2 * Flower +
         A3 * Tree_Canopy_Cover +
         A4 * Road_Island +
         A5 * Bicycle_Lane +
         A6 * Pedestrian_Walkway +
         A7 * car_lanes +
         A8 * tax /

U(sq) = A1 * Ground_Cover +
        A2 * Flower +
        A3 * Tree_Canopy_Cover +
        A4 * Road_Island +
        A5 * Bicycle_Lane +
        A6 * Pedestrian_Walkway +
        A7 * car_lanes +
        A8 * tax
$
Michiel Bliemer
 
Posts: 1705
Joined: Tue Mar 31, 2009 4:13 pm

Re: status quo option

Postby Michiel Bliemer » Fri Jul 07, 2017 7:15 am

Just to add to my reply, please note that the mfrderov algorithm creates designs without attribute level balance. If you require some degree of balance (which is not neededfor model estimation, but many people still see it as a desirable property) then you can consider setting lower and upper bounds on the number of times each attribute level appears within the design. For example,

... A1 * Ground_Cover[10,25,50](6-10,6-10,6-10) + ...

Note that this puts more constraints on the design, making it potentially more difficult to find efficient designs, so you do not want to impose very strict attribute level balance constraints.
Michiel Bliemer
 
Posts: 1705
Joined: Tue Mar 31, 2009 4:13 pm

Re: status quo option

Postby amz » Fri Jul 07, 2017 7:47 am

Thank you very much, much appreciated! I would have not worked that out myself.
All the best
Alberto
amz
 
Posts: 2
Joined: Tue Jul 04, 2017 8:44 pm


Return to Choice experiments - Ngene

Who is online

Users browsing this forum: No registered users and 11 guests