Questions for my DCE survey

This forum is for posts that specifically focus on Ngene.

Moderators: Andrew Collins, Michiel Bliemer, johnr

Questions for my DCE survey

Postby firat85 » Fri Sep 25, 2020 6:17 pm

Dear all,

I'm a beginner in DCE and NGENE and I'm supposed to conduct a DCE survey for my Phd thesis. My topic is waste source separation behaviour of households. I want to measure the willingness to accept compensation of households for separating their wastes at source. I determined a couple of attributes as follows:

Collection frequency - once in a week, three times in a week, everyday (0, 1)
Collection time - evenings, mornings (0, 1)
Waste type - plastic, glass, paper, metal, other (0, 1, 2, 3, 4)
Collection type - self deliver to the collection points (0), taken from home/apartment by collection vehicles (1)
Compensation - 10, 20, 30, 50

I want my choice sets consist of 2 alternatives and 1 opt-out/none, 3 in total. I have no priors for efficient design.

I tried sth like this:
Design
;alts = alt1*, alt2*, optout
;rows = 24
;block =3
;eff = (mnl,d)
;cond:
if(alt1.comp>alt2.comp, alt1.freq<alt2.freq),
if(alt2.comp>alt1.comp, alt2.freq<alt1.freq),
if(alt1.freq>alt2.freq, alt1.comp<alt2.comp),
if(alt2.freq>alt1.freq, alt2.comp<alt1.comp),
if(alt1.waste=0, alt1.comp<50),
if(alt2.waste=0, alt2.comp<50)
;model:
U(alt1) = b0 + b1 * freq[1, 3, 7] + b2 * waste[0, 1, 2, 3, 4] + b3 * coll [0, 1] +
b4 * time[0, 1] + b5 * comp[10, 20, 30, 50] /
U(alt2) = b0 + b1 * freq[1, 3, 7] + b2 * waste[0, 1, 2, 3, 4] + b3 * coll [0, 1] +
b4 * time[0, 1] + b5 * comp[10, 20, 30, 50]
$

My questions are:
1-) Is my code correct? Am I doing right?
2-) I included the opt out, however, when I run the syntax and clicked one of the iterations, I can not see the opt-out alternative among alt1 and alt2. Does it mean that the NGENE has already included it and created the design according to opt-out so I can add it manually to the questionnaire?
3-) Should each respondent be faced the same choice sets in DCE or should I for ex. create 24 sets in 3 blocks like in the code and deliver them randomly to respondents so that they vary?
4-) How should I code the data for estimations in STATA especially how to code the opt out? I know this question is a bit out of topic but would be very grateful if you could also help me about this.

Best
firat85
 
Posts: 7
Joined: Thu Sep 24, 2020 5:19 am

Re: Questions for my DCE survey

Postby Michiel Bliemer » Sat Sep 26, 2020 10:18 am

You are doing a great job with the syntax writing.

1. Your code is technically correct, but you need to dummy code certain attributes, I have made the changes in the syntax below.
2. Ngene includes the optout alternative with U(optout)=0 automatically when it computes the efficiency. Since there are no attribute levels for the optout alternative, Ngene does not produce any output for this alternative so you indeed need to manually add it to your questionnaire.
3. I would use 24 rows in 3 blocks (as in your syntax) so that you randomly assign a block of 8 choice tasks to a respondent. Using 24 rows should have enough variation in your data to estimate more advanced models. Using a design of 8 rows only that you give to all respondents is not recommended.
4. The utility of the optout needs to be fixed to zero.

Below my suggested syntax where I made it easier to read and added dummy coding.

Code: Select all
Design
;alts = waste1*, waste2*, neither
;rows = 24
;block = 3
;eff = (mnl,d)
;cond:
if(waste1.COMP > waste2.COMP, waste1.FREQ < waste2.FREQ), ? ensuring a trade-off between frequency and compensation
if(waste2.COMP > waste1.COMP, waste2.FREQ < waste1.FREQ),
if(waste1.FREQ > waste2.FREQ, waste1.COMP < waste2.COMP),
if(waste2.FREQ > waste1.FREQ, waste2.COMP < waste1.COMP),
if(waste1.TYPE=0, waste1.COMP<50),  ? plastic waste cannot receive high compensation
if(waste2.TYPE=0, waste2.COMP<50)
;model:
U(waste1) = waste[0]
          + freq[0]             * FREQ[1,3,7]
          + type.dummy[0|0|0|0] * TYPE[1,2,3,4,0]
                                  ? 0 = plastic (base)
                                  ? 1 = glass
                                  ? 2 = paper
                                  ? 3 = metal
                                  ? 4 = other
          + coll.dummy[0]       * COLL[1,0]
                                  ? 0 = collected by vehicle from home (base)
                                  ? 1 = self-delivery at collection point
          + time.dummy[0]       * TIME[1,0]
                                  ? 0 = morning (base)
                                  ? 1 = evening
          + comp[0]             * COMP[10,20,30,50]
          /
U(waste2) = waste
          + freq * FREQ
          + type * TYPE
          + coll * COLL
          + time * TIME
          + comp * COMP
$


your conditional constraints on compensation and frequency will lead to a result in which alternatives may have identical COMP and identical FREQ.
So maybe you need to relax your constraint to something like (where I added an equal sign):

if(waste1.COMP >= waste2.COMP, waste1.FREQ < waste2.FREQ)

Michiel
Michiel Bliemer
 
Posts: 1040
Joined: Tue Mar 31, 2009 4:13 pm

Re: Questions for my DCE survey

Postby firat85 » Sat Sep 26, 2020 7:43 pm

Thank you so much for your help Mr. Bliemer. The question marks are now removed from my head. I would like to ask one more question: Should I use interaction terms in my case or when is it necessary to use?
firat85
 
Posts: 7
Joined: Thu Sep 24, 2020 5:19 am

Re: Questions for my DCE survey

Postby Michiel Bliemer » Sun Sep 27, 2020 4:34 pm

If you believe that some interaction effects may be relevant then I would include them, just to make sure that they can be estimated after the data collection.
Michiel Bliemer
 
Posts: 1040
Joined: Tue Mar 31, 2009 4:13 pm

Re: Questions for my DCE survey

Postby firat85 » Sun Sep 27, 2020 7:44 pm

Thank you Mr. Bliemer.
firat85
 
Posts: 7
Joined: Thu Sep 24, 2020 5:19 am


Return to Choice experiments - Ngene

Who is online

Users browsing this forum: Google [Bot] and 1 guest

cron