Beginner - checking if I'm on the right track

This forum is for posts that specifically focus on Ngene.

Moderators: Andrew Collins, Michiel Bliemer, johnr

Beginner - checking if I'm on the right track

Postby socu15_2 » Sat Jan 23, 2021 4:04 am

Hello,
This is the first time I design a choice experiment, which we’re due to pilot soon, and I was wondering if the design is fine.
Any feedback would be helpful. The choice experiment is on health and sustainability claims on chicken products, we are planning on doing a small pre-test (cognitive interviewing), a pilot with 40 people and a total sample of 400. My questions at this stage are mainly:
Does the syntax look ok?
Do these look like too many attributes? (or too many price levels)
Thanks a lot in advance!

Design
; alts = statusquo, alt1*, alt2*
; rows = 28
; block = 2
; eff = (mnl, d)
; alg = swap(stop=total(60 secs))


; model:
U(statusquo) = b01[0.0001] + b2[-0.0001]*price_ref[60]/

U(alt1) = b2* price[60, 80, 100, 120]
+ b3.effects[0.0001]*low_salt[1,0]
+ b4.effects[0.0001]*Safety_certified[1,0]
+ b5.effects[0.0001]*No_antibiotics[1,0]
+ b6.effects[0.0001]*produced_coop[1,0]
+ b7.effects[0.0001]*originSA[1,0]
+ b8.effects[0.0001]*Sustainable[1,0] /

U(alt2) = b2* price[60, 80, 100, 120]
+ b3.effects*low_salt[1,0]
+ b4.effects*Safety_certified[1,0]
+ b5.effects*No_antibiotics[1,0]
+ b6.effects*produced_coop[1,0]
+ b7.effects*originSA[1,0]
+ b8.effects*Sustainable[1,0]
$
socu15_2
 
Posts: 8
Joined: Thu Jan 21, 2021 8:42 pm

Re: Beginner - checking if I'm on the right track

Postby Michiel Bliemer » Sat Jan 23, 2021 11:39 am

The syntax looks fine although I wonder about the utiility function of the status quo, it only has a price attribute, does the status quo have no further characteristics? For example, what is the salt content of the status quo, etc? Usually a status quo alternative has all the same attributes but has specific levels, but maybe you have an entirely different status quo alternative?

Four levels for price is fine.

Seven attributes may be fine but I suggest asking respondents in the pilot study how difficult the choice tasks were and whether they focused on specific attributes. If the choice tasks are too complex, you can consider creating a partial profile design in which only a subset of attributes (e.g., 4 out of 7) is shown in each choice task, see also the Ngene manual.

You have 28 rows with 2 blocks, meaning that each block has 14 choice tasks. This is more than usual and may put a significant burden on the respondent, perhaps consider ;rows = 24 and ;block = 3 such that each respondent faces 8 choice tasks.

Michiel
Michiel Bliemer
 
Posts: 1705
Joined: Tue Mar 31, 2009 4:13 pm

Re: Beginner - checking if I'm on the right track

Postby socu15_2 » Tue Jan 26, 2021 1:04 am

Dear Michiel, thanks a lot, that’s very helpful.
The status quo has the same attributes, in fact, but with all binary variables fixed to zero, so I thought I didn’t have to add those.
Your suggestions for how to reduce burden on respondents seem very reasonable, but I was worried that the sample size of 400 would not be enough if I did more than 2 blocks…
Would a partial profile design also increase the requirements in terms of number of choice cards or sample size?
Thanks again for your response
Regards
S
socu15_2
 
Posts: 8
Joined: Thu Jan 21, 2021 8:42 pm

Re: Beginner - checking if I'm on the right track

Postby Michiel Bliemer » Tue Jan 26, 2021 10:36 am

Have a look at the syntax below where I have included all attributes in the status quo alternative (please check their levels in the require command).
The require commend can only be used with the modified Federov algorithm, and with this algorithm it is wise to apply attribute level constraints for continuous variables (in this case, price, where each level appears 5-7 times within the design). It is not necessary to apply attribute level constraints to categorical variables.

I slightly decreased the number of rows to 24 such that you have two blocks of 12 which also fits with your attributes having 2 and 4 levels, although the modified Federov algorithm will not guarantee strict attribute level balance.

A partial profile design would indeed increase sample size requirements.

Code: Select all
Design
; alts = alt1*, alt2*, sq
; rows = 24
; block = 2
; eff = (mnl, d)
; alg = mfederov(candidates = 2000)
; require:
sq.low_salt = 0,
sq.safety_certified = 0,
sq.no_antibiotics = 0,
sq.produced_coop = 0,
sq.originSA = 0,
sq.sustainable = 0

; model:

U(alt1) = b2[-0.0001]*price[60,80,100,120](5-7,5-7,5-7,5-7)
        + b3.effects[0.0001]*low_salt[1,0]
        + b4.effects[0.0001]*safety_certified[1,0]
        + b5.effects[0.0001]*no_antibiotics[1,0]
        + b6.effects[0.0001]*produced_coop[1,0]
        + b7.effects[0.0001]*originSA[1,0]
        + b8.effects[0.0001]*sustainable[1,0]
        /
U(alt2) = b2*price
        + b3*low_salt
        + b4*safety_certified
        + b5*no_antibiotics
        + b6*produced_coop
        + b7*originSA
        + b8*sustainable
        /
U(sq)   = b0[0.0001]
        + b2*price_sq[60]
        + b3*low_salt
        + b4*safety_certified
        + b5*no_antibiotics
        + b6*produced_coop
        + b7*originSA
        + b8*sustainable
$


Michiel
Michiel Bliemer
 
Posts: 1705
Joined: Tue Mar 31, 2009 4:13 pm

Re: Beginner - checking if I'm on the right track

Postby socu15_2 » Fri Feb 19, 2021 3:04 am

Hello there,
After doing the pre-test we decided on a couple of modifications of the above design about health claims in chicken products:

1. Removed the status quo alterative, and show only two alternatives plus opt-out.
2. Removed the attribute “sustainably produced”.
3. Introduced a constraint so that the attribute “coop” (produced by a farmers’ cooperative) is shown only for local products.

It would be great to know whether the adjusted syntax shown below looks ok, in general but, especially, I was wondering:

1. Do the number of blocks/choice cards seem ok?

12 tasks per respondent seemed fine in the pre-test and tried to stick to 1 block because I’m worried about sample size (400, in principle) not being
sufficient after removing the status quo alternative.

2. Are there reasons to think that a sample of 400 will not be enough with the current design?

I’m basing this on the rule of thumb provided by Orme (2010) where minimum sample size would be approx. [MinSample=500*(max levels for any attribute)/(tasks*alternatives)] (If I'm interpreting this correctly, the number of attributes would not affect minimum sample size…)

Again, many thanks for your help

Design
; alts = alt1*, alt2*
; rows = 12
; block = 1
; eff = (mnl, d)
; alg = swap(stop=total(60 secs))

;cond:
if(alt1.originSA = 0, alt1.coop = 0),
if(alt2.originSA = 0, alt2.coop = 0)

; model:

U(alt1) = b2[-0.0001]*price[60,80,100,120]
+ b3.effects[0.0001]*low_salt[1,0]
+ b4.effects[0.0001]*safety_certified[1,0]
+ b5.effects[0.0001]*no_antibiotics[1,0]
+ b6.effects[0.0001]*originSA[1,0]
+ b7.effects[0.0001]*coop[1,0]

/
U(alt2) = b2*price
+ b3*low_salt
+ b4*safety_certified
+ b5*no_antibiotics
+ b6*originSA
+ b7*coop[1,0]
$
socu15_2
 
Posts: 8
Joined: Thu Jan 21, 2021 8:42 pm

Re: Beginner - checking if I'm on the right track

Postby Michiel Bliemer » Fri Feb 19, 2021 9:19 am

1. 12 choice tasks does not give you much variation in your data. It would be better to use ;rows = 24 and ;block = 2, such that you create 2 versions of your survey.
2. You did not include an optout alternative, so if you need that, please add optout to ;alts = ... and also add a constant to the utility of alt1 and alt2.
3. Using priors from a pilot study could give you an indication of sample size needed. Without good priors it is impossible to say how much sample size you need. 400 sounds fine, your experiment is not very complicated.

Michiel
Michiel Bliemer
 
Posts: 1705
Joined: Tue Mar 31, 2009 4:13 pm


Return to Choice experiments - Ngene

Who is online

Users browsing this forum: Google [Bot] and 6 guests

cron