Feedback on constrained design

This forum is for posts that specifically focus on Ngene.

Moderators: Andrew Collins, Michiel Bliemer, johnr

Feedback on constrained design

Postby jmpenn311 » Sat Jan 30, 2021 12:49 am

Greetings,
I am designing a DCE for WTA and would like to ask for feedback concerning the constraint. There are no past studies on the topic so using benign priors. When imposing a nesting constraint: "If D=0, then E=0", the frequency of D level 0 is concerningly low, appearing in only 4 of the 48 profiles. While I understand that more efficient designs may come at the expense of level balance, is this frequency too low? It seems that efficiency is lost by having so few comparisons of levels 1,2,and 3 of D relative to level 0. I also understand (and tried) that nesting overrules attribute level frequency/range imposed in the design.

Code: Select all
Design
     ;alts=alt1, alt2
     ;rows=24
     ;eff=(mnl,d)
     ;rep=500
     ;block=3
     ;cond:
     if(alt1.D=0, alt1.E=0),
     if(alt2.D=0, alt2.E=0)
     ;model:
     U(alt1) = b1[0.01]*Price[190, 195, 200, 205] +
               b2.dummy[-.001] *A[1,0] +
               b3.dummy[.002|.001]  *B[2,1,0] +
               b4.dummy[.001]  *C[2,1]  +
               b5.dummy[.002|.002|.001]  *D[3,2,1,0]  +
               b6.dummy[.003|.002|.002|.001]  *E[4,3,2,1,0] +
               i1[.001]*D*E
         /
     U(alt2) = b1*Price +
               b2*A +
               b3*B +
               b4*C +
               b5*D +
               b6*E
$
jmpenn311
 
Posts: 3
Joined: Tue Aug 18, 2020 4:13 am

Re: Feedback on constrained design

Postby Michiel Bliemer » Mon Feb 08, 2021 7:02 pm

Apologies for my late response. It is correct that the most efficient design has only a few choice tasks where D = 0. I confirmed this by using a different algorithm, which also shows the same.

Code: Select all
Design
;alts=alt1, alt2
;rows=24
;eff=(mnl,d)
;block=3
;alg = mfederov
;reject:
alt1.D = 0 and alt1.E > 0,
alt2.D = 0 and alt2.E > 0
;model:
U(alt1) = b1[0.01]*Price[190, 195, 200, 205] +
          b2.dummy[-.001] *A[1,0] +
          b3.dummy[.002|.001]  *B[2,1,0] +
          b4.dummy[.001]  *C[2,1]  +
          b5.dummy[.002|.002|.001]  *D[3,2,1,0]  +
          b6.dummy[.003|.002|.002|.001]  *E[4,3,2,1,0] +
          i1[.001]*D*E
        /
U(alt2) = b1*Price +
          b2*A +
          b3*B +
          b4*C +
          b5*D +
          b6*E
$


The reasons that this happens is due to the specific constraint. Attribute E has 5 levels and the each level needs to appear a sufficient number of times to be able to estimate all dummy coded coefficients. Only if D > 0 can E attain all five levels, so for efficiency reasons D = 0 is avoided as much as possible, but is included a sufficient number of times to allow estimating the dummy coded coefficients of b5. When I run the syntax above, there are 5 choice tasks (out of 24) with D = 0 either for alt1 or alt2.

Michiel
Michiel Bliemer
 
Posts: 1705
Joined: Tue Mar 31, 2009 4:13 pm

Re: Feedback on constrained design

Postby jmpenn311 » Wed Feb 10, 2021 4:05 am

Thank you for the feedback
jmpenn311
 
Posts: 3
Joined: Tue Aug 18, 2020 4:13 am

Re: Feedback on constrained design

Postby bassieeco » Fri Oct 01, 2021 11:35 am

Dear all,
I am conducting a DCE to estimate the WTA with two generic alternatives (Alternative A and B), one alternative mixed ( fixed and randomly vary ) values of attribute levels (Alternative C) and an opt-out option. To avoid the unrealistic combination, I have used; require and; reject. Here is my design followed by questions:

design
;alts=altA*,altB*,altC*,OptOut
;rows=24
;block=3
;eff = (mnl,d,median)
;alg = mfederov(candidates = 5000)

;require:
altC.IHQ=1,
altC.SNR=1,
altC.EO<altA.EO,
altC.EO<altB.EO,

altC.comp>altA.comp,
altC.comp> altB.comp
; reject:
altA.SNR=2 and altA.SE=4,
altB.SNR=2 and altB.SE=4

;model:
U(altA) =b1.effects[(n,0.00000001,0.0000000001)|(n,0.00000001,0.0000000001)]*IHQ[3,2,1]
+b2.effects[(n,0.00000001,0.0000000001)|(n,0.00000001,0.0000000001)|(n,0.00000001,0.0000000001)]*SE[4,3,2,1]
+b3.effects[(n,0.00000001,0.0000000001)|(n,0.00000001,0.0000000001)|(n,0.00000001,0.0000000001)]*SNR[4,3,2,1]
+b4[(n, 0.00000001,0.0000000001)]*EO[0,150,300,450]
+b5[(n, 0.00000001,0.0000000001)]*comp[200,300,400,500,600,700]/
U(altB) =b1*IHQ
+b2*SE
+b3*SNR
+b4*EO
+b5*comp/

U(altC) =B0+b1*IHQ
+b2*SE
+b3*SNR
+b4*EO
+b5*comp/
U(OptOut) =None[-0.00000001]$

Questions
1. Alternative C is constrained to have both fixed and randomly vary values of attribute levels. Does this will have an impact on the efficiency of the design and estimation of the model later on?
2. As a result of the constraint stated in (1), lower compensation to the respondents seems unrealistic. So I constrained compensation presented to the respondents in Alternative C is to be higher than Alternative A and B. Does this may force the respondents to choose only Alternative C or may affect the efficiency of the design?
3. Regarding the opt-out option- I want to provide a chance for respondents to choose their current practices, which will be elicited by follow up questions if they choose an opt-out option. In An opt-out option, I do not have specific values for 4 of the attributes, I have only $0 for the compensation attribute. Any suggestion on how to design to include opt-out in such cases?
Thanks in advance
bassieeco
 
Posts: 4
Joined: Wed Aug 18, 2021 11:28 am

Re: Feedback on constrained design

Postby Michiel Bliemer » Sun Oct 03, 2021 10:52 am

1. It is fine to have some attributes fixed and others that vary as long as it is realistic.

2. Any constraint you impose decreases the efficiency of the design, so you only want to impose constraints to avoid unrealistic choice tasks.

3. An opt-out typically has no attributes. When you refer to "current practices", you seem to refer to a status quo alternative, which DOES have attributes. So if you actually refer to a status quo alternative you will need to specify its complete utility function with the attribute values fixed to indicate specific values. If the status quo alternative is different for different people, you may need to create different designs for different status quo alternatives.

Michiel
Michiel Bliemer
 
Posts: 1705
Joined: Tue Mar 31, 2009 4:13 pm

Re: Feedback on constrained design

Postby bassieeco » Tue Oct 05, 2021 5:18 pm

Thank you very much, appreciated !
bassieeco
 
Posts: 4
Joined: Wed Aug 18, 2021 11:28 am


Return to Choice experiments - Ngene

Who is online

Users browsing this forum: No registered users and 4 guests

cron