No Valid design due to potential misspecifications

This forum is for posts that specifically focus on Ngene.

Moderators: Andrew Collins, Michiel Bliemer, johnr

No Valid design due to potential misspecifications

Postby Carla_B » Thu Feb 11, 2021 11:39 pm

Dear all,

I am still learning about CE and I would like to have your insights into a problem I am facing.

I am trying to make a D-efficient (before making a Bayesian efficient one) for a CE presenting 3 varieties alternatives to farmers: 2 hypothetical varieties (alt1 and alt2) and 1 reference that is commonly used by farmers (alt3).

I have conducted a pilot (N=40) to get priors to be included in the following design. I have only included the priors that have a significant value and put a "0" value for the others.

The problem is I can't seem to obtain a valid design after 1000 evaluations. NGene sends back the following message:
"There may be a problem with the specification of the design. A common problem is that the choice probabilities are too extreme (close to 1 and 0), perhaps because some or all of the prior values are too large".

Would you be able to help and point me towards the right direction/paper to solve the issue?

The design is the following:

Design

;alts = alt1, alt2, alt3
;rows = 18
;block = 3
;eff = (mnl,d)
; model:

U(alt1) = b1.dummy[1.100|0]*yld[2,1,0] + b2.dummy[0|0]*mat[2,1,0] + b3.dummy[0|0]*dor[2,1,0] + b4.dummy[1.565|1.648]*lbr[2,1,0] + b5.dummy[0.798|1.051]*tbs[2,1,0] + b6[-0.001]*pri[1800,2300,2700,3500,3800,4200]/
U(alt2) = b1*yld + b2*mat + b3*dor + b4*lbr + b5*tbs + b6*pri/
U(alt3) = b0[0] + b7[1.100]*yldref[1] + b8[0]*matref[1] + b9[0]*dorref[0] + b10[0]*lbrref[0] + b11[1.051]*tbsref[1] + b6*priref[3250] $


Best wishes,

Carla
Carla_B
 
Posts: 3
Joined: Thu Feb 11, 2021 1:40 am

Re: No Valid design due to potential misspecifications

Postby Carla_B » Sat Feb 13, 2021 1:11 am

Hi all,

As a follow up from my previous message, It looks like the problem comes from specifying the utility of the reference alternative (all attribute levels known). If I don't include a utility function for alt3 but instead include the corresponding constant in alt1 and alt2, then NGene produces a design. Would that be a valid alternative?

Best wishes,

Carla
Carla_B
 
Posts: 3
Joined: Thu Feb 11, 2021 1:40 am

Re: No Valid design due to potential misspecifications

Postby Michiel Bliemer » Sat Feb 13, 2021 3:55 pm

I believe that the syntax below does what you are looking for, I have made several changes. The reason why your syntax did not work is because you used different parameters for alt3 and since these levels do not vary these parameters cannot be estimated. But you can estimate generic parameters across the three alternatives as I have done below.

Code: Select all
Design
;alts = alt1*, alt2*, alt3
;rows = 18
;block = 3
;eff = (mnl,d)
;alg = mfederov(candidates = 2000)
;require:
alt3.yld = 1,
alt3.mat = 1,
alt3.dor = 0,
alt3.lbr = 0,
alt3.tbs = 1
; model:
U(alt1) = b1.dummy[1.100|0]*yld[2,1,0]
        + b2.dummy[0|0]*mat[2,1,0]
        + b3.dummy[0|0]*dor[2,1,0]
        + b4.dummy[1.565|1.648]*lbr[2,1,0]
        + b5.dummy[0.798|1.051]*tbs[2,1,0]
        + b6[-0.001]*pri[1800,2300,2700,3500,3800,4200](2-4,2-4,2-4,2-4,2-4,2-4)
        /
U(alt2) = b1*yld + b2*mat + b3*dor + b4*lbr + b5*tbs + b6*pri
        /
U(alt3) = b0[0] + b1*yld + b2*mat + b3*dor + b4*lbr + b5*tbs + b6*pri_ref[3250]
$


Michiel
Michiel Bliemer
 
Posts: 1705
Joined: Tue Mar 31, 2009 4:13 pm

Re: No Valid design due to potential misspecifications

Postby Carla_B » Mon Feb 15, 2021 7:27 pm

Dear Michiel,

Thank you very much for your answer. Your syntax works indeed. That's really helpful.

Have a nice day,

Carla
Carla_B
 
Posts: 3
Joined: Thu Feb 11, 2021 1:40 am


Return to Choice experiments - Ngene

Who is online

Users browsing this forum: Google [Bot] and 6 guests

cron