Labeled SCE with a constrained design

This forum is for posts that specifically focus on Ngene.

Moderators: Andrew Collins, Michiel Bliemer, johnr

Labeled SCE with a constrained design

Postby jonnyK123 » Mon Apr 11, 2022 7:31 pm

Dear all,

i´ve been runnig in some issues to create a d-efficient design for the following stated choice experiments using the software package Stata.

SCE for 4 labeled alternatives (first { } referes to alt1, second { } to alt2 and so forth):

Attribute1: {2, 7, 14}; {0} ; {0, 1, 2}; {0}
Attribute2: {0}; {2, 4}; {0}; {0}
Attribute3: {10, 20, 60}; {0}; {0}; {0}
Attribute4: {0}; {2, 3, 5}; {1, 2, 3}; {1, 2, 3}
Attribute5: {30} ; {16, 24, 32}; {80, 90, 100}; {80, 90, 100, 122.5, 125}


The goal is to present each respondent a block of 6 choice sets. Each Prior can be assumed as a very small negative.

Unfortunatly, I have no experience with Ngene. That is why I would like to ask if Ngene is capable of creating a d-efficient design for this particular SCE. And if so, is the code rather trivial or is it more complex?

Many thanks in advance,

Jonas
jonnyK123
 
Posts: 4
Joined: Sun Apr 10, 2022 11:53 pm

Re: Labeled SCE with a constrained design

Postby Michiel Bliemer » Tue Apr 12, 2022 10:55 am

That would be fairly straightforward in Ngene. If I understand your setup correctly, the following script in Ngene would generate the required design (assuming that all variables are numerical, if some are categorical then dummy coding is required):

Code: Select all
design
;alts = alt1, alt2, alt3, alt4
;rows = 30
;block = 5
;eff = (mnl,d)
;model:
U(alt1) = asc1[0]
        + b1[0]   * A1[2,7,14]
        + b2[0]   * B1[0]
        + b3[0]   * C1[10,20,60]
        + b4[0]   * D1[0]
        + b5[0]   * E1[30]
        /
U(alt2) = asc2[0]
        + b1      * A2[0]
        + b2      * B2[2,4]
        + b3      * C2[0]
        + b4      * D2[2,3,5]
        + b5      * E2[16,24,32]
        /
U(alt3) = asc3[0]
        + b1      * A3[0,1,2]
        + b2      * B3[0]
        + b3      * C3[0]
        + b4      * D3[1,2,3]
        + b5      * E3[80,90,100]
        /
U(alt4) = b1      * A4[0]
        + b2      * B4[0]
        + b3      * C4[0]
        + b4      * D4[1,2,3]
        + b5      * E4[80,90,100,122.5,125]
$


I used zero priors in the above. Using small positive or negative priors to indicate the sign of the parameter is only useful when checking for dominant alternatives (which typically do not exist in a labelled experiment) so you may as well be using zero priors in that case until you have done a pilot study.

I used 30 rows since you have attributes with 2, 3, and 5 levels. 30 is divisible by 2, 3, and 5 and hence the design will be attribute level balanced. I used 5 blocks because that will give you blocks of 6 choice sets.

Michiel
Michiel Bliemer
 
Posts: 1430
Joined: Tue Mar 31, 2009 4:13 pm

Re: Labeled SCE with a constrained design

Postby jonnyK123 » Tue Apr 12, 2022 6:14 pm

Dear Michiel,

thanks you so much for your reply and your uselful tips.
jonnyK123
 
Posts: 4
Joined: Sun Apr 10, 2022 11:53 pm


Return to Choice experiments - Ngene

Who is online

Users browsing this forum: No registered users and 3 guests