Question about efficient design

This forum is for posts covering broader stated choice experimental design issues.

Moderators: Andrew Collins, Michiel Bliemer, johnr

Question about efficient design

Postby Peter_C » Tue Jun 23, 2020 5:37 pm

Dear Michiel,

I need some help/advice from you.

I would like to do a research with use of labelled alternatives but I have some questions about the design.

I have 3 labelled alternatives with three attributes. From these attributes, one is an alternative specific, and the others are generic.

I would like to estimate MNL, LC and possibly RPL models later.

In this situation, should I specify firstly an MNL design and after that an RPL design?

I wrote the following syntax:

design
;alts = car, bus, rail
;rows = 8
;eff = (mnl,d)
;con
;model:
U(car) = b1[-0.2] + b2[-0.1] * price[750,850] + b3[0.8] * service[1,2,3] + b4[1.2] * type[1,2] /
U(bus) = b1[0.9] + b2 * price[550,650] + b3*service + b4*type /
U(rail) = b2 * price[350,450] + b3*service + b4*type
$

design
;alts = car, bus, rail
;rows = 8
;eff= (rp,d)
;con
;rdraws = halton(500)
;model:
U(car) = b1[-0.2] + b2[n,-0.1,0.5] * price[750,850] + b3[n,0.8,0.4] * service[1,2,3] + b4[n,1.2,0.4] * type[1,2] /
U(bus) = b1[0.9] + b2 * price[550,650] + b3*service + b4*type /
U(rail) = b2 * price[350,450] + b3*service + b4*type
$

Can these forms are suitable for my later purposes? (of course, I would like to use the RP design in the survey)

Also, I have some concerns about whether the ";con" command is really necessary? (whether it is necessary to
estimate of alternative specific constant?, and in my syntax I specified the "b1" for the alternative
specific constant and in the third alternative I leave that empty because I would like to keep that on base value in estimates. Is this appropriate in this form?

Thank you very much your help!

Best regards,
Peter
Peter_C
 
Posts: 14
Joined: Sat Jun 20, 2020 12:16 am

Re: Question about efficient design

Postby Michiel Bliemer » Wed Jun 24, 2020 11:07 am

You should optimise the design for an MNL model, it is almost impossible to optimise your design for estimating a panel mixed logit model (rppanel in Ngene. Optimising for MNL still allows you to estimate latent class and mixed logit models.

There are several issues with your syntax:

1. The number of rows is too small to create enough variation to estimate latent class or mixed logit models. I suggest increasing the number of rows and block the design.

2. You need to specify two different constants, so you cannot call both constants b1. Given that you have 3 labelled alternatives, you need 2 constants, so I would recommend adding ;con. You indeed do not include a constant for the third alternative.

3. The prior for price is far too large, please use appropriate priors from a pilot study or set them (close) to zero if you are unsure.

4. If you are using different price levels, you should give the price attributes different names.

Below an example of the syntax that would work.

Code: Select all
design
;alts = car, bus, rail
;rows = 16
;block = 2
;eff = (mnl,d)
;con
;model:
U(car)  = a1[-0.2]
        + b2[-0.001] * price_car[750,850]
        + b3[0.8] * service[1,2,3]
        + b4[1.2] * type[1,2]
        /
U(bus)  = a2[0.9]
        + b2 * price_bus[550,650]
        + b3 * service
        + b4 * type
        /
U(rail) = b2 * price_rail[350,450]
        + b3 * service
        + b4 * type
$


Michiel
Michiel Bliemer
 
Posts: 1705
Joined: Tue Mar 31, 2009 4:13 pm

Re: Question about efficient design

Postby Peter_C » Thu Jun 25, 2020 2:55 am

Thank you Professor!

You helped a lot!

I would like to ask that, when I use blocks, all that matters is that the two blocks are in the same proportion in the database?

Does it matter how randomly the blocks are distributed among the respondents?

Regards,
Peter
Peter_C
 
Posts: 14
Joined: Sat Jun 20, 2020 12:16 am

Re: Question about efficient design

Postby Michiel Bliemer » Thu Jun 25, 2020 10:07 am

It does not matter how you distribute the blocks to respondents, as long as they appear more or less equally in the data (e.g. 2 blocks that appear 45-55% is fine, but 10-90% is not).

Michiel
Michiel Bliemer
 
Posts: 1705
Joined: Tue Mar 31, 2009 4:13 pm


Return to Choice experiments - general

Who is online

Users browsing this forum: No registered users and 4 guests

cron