End points design?

This forum is for posts that specifically focus on Ngene.

Moderators: Andrew Collins, Michiel Bliemer, johnr

End points design?

Postby iris.vanermen » Sat Dec 28, 2019 7:07 am

Hi all,

I am currently designing a choice experiment with 4 categorical attributes (all have 3 levels) and 1 monetary attribute with 4 levels, using following syntax:

Design

;alts = A*, B*, OO

;rows = 18

;block = 3

;eff = (mnl, d, mean)

;bdraws = halton(100)

;alg = mfederov(candidates=1000)

;reject:

A.Erosion = 3 and A.Carbon = 1,
B.Erosion = 3 and B.Carbon = 1,
A.Carbon = 3 and A.Erosion = 1,
B.Carbon = 3 and B.Erosion = 1

;model:


U(A) = B1[(n, -0.1, 0.1)] * Price[5, 7, 9, 11]
+ B2.dummy [(n, 0.1, 0.05)|(n, 0.15, 0.075)] * Biodiversity[2,3,1]
+ B3.dummy [(n, 0.1, 0.05)|(n, 0.15, 0.075)] * Water[2,3,1]
+ B4.dummy [(n, 0.1, 0.05)|(n, 0.15, 0.075)] * Erosion[2,3,1]
+ B5.dummy [(n, 0.1, 0.05)|(n, 0.15, 0.075)] * Carbon[2,3,1] /

U(B) = B1 * Price
+ B2.dummy * Biodiversity
+ B3.dummy * Water
+ B4.dummy * Erosion
+ B5.dummy * Carbon /

U(OO) = ASC[(n, 0, 0.1)]
$

I've tried different priors and dummy and effects type coding, but for the price attribute, the lowest and highest level appear a lot more often then the other levels (7: 4 times and 9: only 1 time over both alternatives). This seems strange to me? Does anyone have an idea why this is the case and how I could create more level balance for this attribute?

Thanks in advance!
Best regards,
Iris

Below the design that comes out:

Choice situation a.price a.biodiversity a.water a.erosion a.carbon b.price b.biodiversity b.water b.erosion b.carbon Block
1 11 2 2 3 3 5 1 3 1 2 1
2 5 3 3 3 2 9 2 1 2 3 3
3 5 1 2 2 3 5 2 1 1 1 3
4 11 3 1 1 1 5 2 2 3 2 2
5 5 3 1 2 2 11 2 2 3 3 3
6 5 2 1 1 2 11 1 3 2 1 2
7 11 3 2 2 1 5 2 3 3 3 3
8 11 2 2 1 2 5 1 1 3 3 2
9 5 2 3 2 1 5 3 1 3 3 1
10 5 1 2 1 1 11 3 3 2 2 1
11 7 2 3 2 3 5 3 2 1 1 1
12 5 3 2 2 3 9 1 3 3 2 2
13 11 3 1 3 3 5 2 2 2 2 2
14 5 2 1 2 1 11 3 3 1 2 1
15 5 3 1 3 2 5 1 2 2 3 1
16 7 1 1 2 2 5 3 3 1 1 3
17 5 3 3 2 3 9 1 2 3 2 2
18 5 1 3 2 1 7 3 2 1 2 3
iris.vanermen
 
Posts: 2
Joined: Thu Dec 26, 2019 11:56 pm

Re: End points design?

Postby Michiel Bliemer » Sat Dec 28, 2019 12:18 pm

The modified Federov algorithm optimises efficiency without satisfying attribute level balance (unlike the default swapping algorithm). For variables that are not dummy or effects coded, this generally leads to extreme (end point) values since this is more efficient, namely the larger the trade-offs, the smaller the standard errors of the parameter estimates. For dummy and effects coded attributes, levels will automatically have a high degree of balance (e.g. if a level appears only a few times it will have a high standard error and make the design inefficient).

I can understand that you may desire some level of attribute level balance for all attributes, so when using the modified Federov algorithm we recommend applying constraints on the number of times each level appears within the design. Simply replace:

Price[5, 7, 9, 11]

with:

Price[5, 7, 9, 11](4-5,4-5,4-5,4-5)

This ensures that each level appears 4 or 5 times within your 18 rows.

Please refer to page 139 of the manual (underneath Figure 8.2).

Best wishes,
Michiel
Michiel Bliemer
 
Posts: 953
Joined: Tue Mar 31, 2009 4:13 pm

Re: End points design?

Postby iris.vanermen » Mon Dec 30, 2019 3:45 am

Thank you very much for your quick and very clear reply!

Best regards
iris.vanermen
 
Posts: 2
Joined: Thu Dec 26, 2019 11:56 pm


Return to Choice experiments - Ngene

Who is online

Users browsing this forum: No registered users and 4 guests

cron