choice-metrics.com

Hello,

I am designing a simple between-subject experiment in which the respondents are split into a treatment/control group. My goal is to test whether the treatment affects the preference for the attributes/levels.

In the past, I tried to use the treatment covariates, but I was not successful (see this discussion http://choice-metrics.com/forum/viewtopic.php?f=2&t=404#p1487. This time, I am trying to use scenarios.

The CE is very simple, with only 2 attributes with 2 levels each.
To exemplify, I am using the full factorial design.

Code: Select all

Design
;alts = alt1, alt2
;rows = all
;fact
;model:
U(alt1) = ASC1[-0.8]
        + b1.dummy[0.9] * A[1,0]
        + b2.dummy[1.0] * B[1,0]
        /
U(alt2) = b1            * A
        + b2            * B
$


This code generates 16 choice tasks.

I am trying to include the experiment's treatment/control variable as a scenario (the T attribute), and I wrote this code:

Code: Select all

Design
;alts = alt1, alt2
;rows = all
;fact
;model:
U(alt1) = ASC1[-0.8]
        + bT.dummy[0.5] * T[1,0]
        + b1.dummy[0.9] * A[1,0]
        + b2.dummy[1.0] * B[1,0]
        + iAT[0.6]      * A * T.dummy[1]
        + iBT[0.7]      * B * T.dummy[1]
        /
U(alt2) = bT            * T[T]
        + b1            * A
        + b2            * B
        + iAT           * A * T
        + iBT           * B * T
$


This generates 32 choice tasks, basically duplicating the previous one.
It seems to work and I get no errors, but I am afraid something is not right.

Specifically, the part of the code defining the treatment dummy bT.dummy[0.5] * T[1,0] should add to the ASC1, but it should not be included in the alternative 2. However, if I eliminate the code bT * T[T], the variable alt2.t appears anyway, and is not anymore the same as
alt1.t.

I guess a better function would exclude the treatment constant and include the interaction term between the ASC and the treatment. However, I do not know how to do it. Do you have any suggestion?

You are correct that you need to remove bT * T from alt2. The reason that Ngene adds T back into alt2 is because you are using T in the interaction with A and B and each attribute has its own attribute levels, you cannot borrow levels from another alternative unless you explicitly specify so.

You need to add:
;require:
alt1.T = alt2.T

The script then becomes:

Code: Select all

Design
;alts = alt1, alt2
;rows = all
;require:
alt1.T = alt2.T
;fact
;model:
U(alt1) = ASC1[-0.8]
        + bT.dummy[0.5] * T[1,0]
        + b1.dummy[0.9] * A[1,0]
        + b2.dummy[1.0] * B[1,0]
        + iAT[0.6]      * A * T.dummy[1]
        + iBT[0.7]      * B * T.dummy[1]
        /
U(alt2) = b1            * A
        + b2            * B
        + iAT           * A * T
        + iBT           * B * T
$

You could also consider an efficient design, such as

Code: Select all

Design
;alts = alt1, alt2
;rows = 24
;block = 2
;alg = mfederov
;require:
alt1.T = alt2.T
;eff = (mnl,d)
;model:
U(alt1) = ASC1[-0.8]
        + bT.dummy[0.5] * T[1,0]
        + b1.dummy[0.9] * A[1,0]
        + b2.dummy[1.0] * B[1,0]
        + iAT[0.6]      * A * T.dummy[1]
        + iBT[0.7]      * B * T.dummy[1]
        /
U(alt2) = b1            * A
        + b2            * B
        + iAT           * A * T
        + iBT           * B * T
$

Michiel