choice-metrics.com

Dear Sir,
This is the first time I use Ngene to design a DCE questionnaire and I don't have much knowledge of statistics, so I hope you will forgive me for having a lot of doubts.
The model is simple, we have 2 unlabeled alternatives (plus a third opt-out) with three attributes each: the first two refer to features of a screening programme (each with only two levels) and the third attribute is wtp (with 4 levels). The model and results are as follows:

Design
;alts = alt1*, alt2*, alt3
;rows = 12
;eff=(mnl,wtp(wtp1))
;wtp=wtp1(b1,b2,b4,b5/b3)
;cond:
if(alt1.A=alt2.A and alt1.B=alt2.B,alt1.C=alt2.C)
;model:
U(alt1)=b0[0.5]+b1[2.1]*A[0,1]+b2[2.3]*B[0,1]+b3[-0.5]*C[0,1,2,3] /
U(alt2)=b4[2.1]*A+b5[2.3]*B+b3*C
$

MNL efficiency measures
D error 1.220029
A error 2.232028
B estimate 35.53194
S estimate 3.30665
WTP(wtp1) estimate 60.373969
WTP(wtp1) n 3.520091
D optimality 58.593736%

My questions are:
- Have I specified the model correctly, is anything relevant missing?
- Is it better to use the instruction ";eff=(mnl,wtp(wtp1))
;wtp=wtp1(b1,b2,b4,b5/b3)" or the ";eff=(mnl,d)" statement?
- What are the efficiency measures I should take into account? What is an acceptable range of values for these measures?
- We know the prior values of the parameters (from a pre-pilot) but not the value of the constant. What value should I set?
- Is it correct to consider that the sample size can be calculated as: (S estimate*number of parameters), so = 3.31 * 6 = 20? Isn't it a very small sample?

Thank you very much for your attention,
Majose

There may be some issues with your specification:

* You indicate that al1 and alt2 are generic/unlabelled by adding an asterisk (*), but you specify alternative-specific coefficients for them. So you either need to remove the asterisk, or you need to use generic coefficients. See the two scripts below.

* You only add a constant to alt1, but you have alt3 as an opt-out alternative. This means that you must also add a constant to alt2. This constant needs to be the same as the constant in alt1 if the alternatives are generic, or can be different of the alternatives are labelled.

* Is C a numerical attribute? If it is a categorical attribute, you need to specify it as b3.dummy[..|..|..] * C[1,2,3,0] where 0 is the base level and put dummy coded priors on the dots for levels 1, 2, and 3.

To answer your questions:
- I typically use ;eff = (mnl,d), which is what almost everyone would do. Optimising specifically for WTP is not common, but it is possible.
- There exists no particular ranges for the D-error and A-error since these are study-specific. I generally ignore B (utility balance) estimates. Your S estimates suggests that with 4 respondents filling out 12 choice tasks each you should be able to estimate all coefficients at a statistically significant level. So in this case 4 would be enough already and yes this is low. So if you are collecting data from hundreds or thousands of respondents you should easily be able to estimate this model. Of course this assumes that your priors are correct.
- You should estimate the constant(s) using your pilot data, you should not guess them.

Btw, your constraint is quite unusual?

Code: Select all

Design  ? if alt1 and alt2 are labelled
;alts = alt1, alt2, alt3
;rows = 12
;eff=(mnl,d)
;cond:
if(alt1.A=alt2.A and alt1.B=alt2.B,alt1.C=alt2.C)
;model:
U(alt1) = asc1[0.5]
        + b1[2.1]    * A[0,1]
        + b2[2.3]    * B[0,1]
        + b3[-0.5]   * C[0,1,2,3]
        /
U(alt2) = asc2[0.5]   
        + b4[2.1]    * A
        + b5[2.3]    * B
        + b3         * C
$

Code: Select all

Design  ? if alt1 and alt2 are unlabelled
;alts = alt1*, alt2*, alt3
;rows = 12
;eff=(mnl,d)
;cond:
if(alt1.A=alt2.A and alt1.B=alt2.B,alt1.C=alt2.C)
;model:
U(alt1) = asc[0.5]
        + b1[2.1]    * A[0,1]
        + b2[2.3]    * B[0,1]
        + b3[-0.5]   * C[0,1,2,3]
        /
U(alt2) = asc
        + b1         * A
        + b2         * B
        + b3         * C
$

Michiel

Dear Michiel,
Thank you very much for your explanations! I will test the model again on the basis of your instructions.
Best regards
Majose