choice-metrics.com

Hi, I wrote the following Ngene code for a DCE with two alternatives. However, Ngene fails to find an initial design and I don't understand why that is.
Can you help me?

Here is the code:

Code: Select all

Design
;alts = alt1*, alt2*
;rows = 24
;block = 3
;eff = (mnl, d)
;rep = 500
;model:
U(alt1) = b1[0.9]                      * W[1,2,3]
        + b2.dummy[0.3|0|0]                * O[1,2,3,4]
        + b3.dummy[0.2|0.1|0.1]          * G[1,2,3,4]

        + b51[0]                          * O.dummy[1]*G.dummy[1]
        + b52[0]                          * O.dummy[1]*G.dummy[2]
        + b53[0]                          * O.dummy[1]*G.dummy[3]
        + b54[0]                          * O.dummy[2]*G.dummy[1]
        + b55[0]                          * O.dummy[2]*G.dummy[2]
        + b56[0]                          * O.dummy[2]*G.dummy[3]
        + b57[0]                          * O.dummy[3]*G.dummy[1]
        + b58[0]                          * O.dummy[3]*G.dummy[2]
        + b59[0]                          * O.dummy[3]*G.dummy[3]
        /

U(alt2) = b1                           * W
        + b2                           * O
        + b3                           * G

        + b51                          * O.dummy[1]*G.dummy[1]
        + b52                          * O.dummy[1]*G.dummy[2]
        + b53                          * O.dummy[1]*G.dummy[3]
        + b54                          * O.dummy[2]*G.dummy[1]
        + b55                          * O.dummy[2]*G.dummy[2]
        + b56                          * O.dummy[2]*G.dummy[3]
        + b57                          * O.dummy[3]*G.dummy[1]
        + b58                          * O.dummy[3]*G.dummy[2]
        + b59                          * O.dummy[3]*G.dummy[3]
$



The default swapping algorithm will not be able to find a feasible design because there exist a very large number of dominant alternatives since you only have 3 attributes and finding 24 rows without any dominant alternative is not possible with a column-based algorithm.
The easy solution is to switch to a row-based algorithm by adding the following property:

;alg = mfederov

This algorithm does not guarantee attribute level balance. It will be reasonably balanced for dummy coded attributes, but for your numerical attribute W you could consider using W[1,2,3](6-10,6-10,6-10), to ensure that each level appears between 6 and 8 times across the 24 rows (where 8 times would be perfectly attribute level balanced).

Note that you do not need ;rep, so you can remove that from the script.

Michiel

Thank you so much for your explanation and helpful suggestion, that helped!