optimal design with 8 choice..is it possible?

[Tiziana]

Dear all
I write in this forum because I have some doubt about the "ood" code.
My design consists of 3 attributes. The first one is the price with 4 levels, the second and the third attributes are dummy codes. Since I am also interested in the interaction beetween the second and the third attributes I run the following codes:
Design
;alts = alt1, alt2
;rows = 8
;orth = ood
;model:
U(alt1) = b1 * PR[0,1,2,3] + b2 * NCL [0,1] + b3 * NCS [0,1] + b4 * NCL * NCS/
U(alt2) = b1 * PR + b2 * NCL + b3 * NCS + b4 * NCL * NCS
$


Te D efficiency is 96.656%. First, according to me, it is very strange that with 4*2*2 choice design is to find a design with D-efficiency of 96%, also considering some interaction . Another doubt I have is that I get a duplicate and then I have to drop one choice situation with 12 rows.
However, using Burguess & Street design, I used to get 24 choice situations. In other words, is Ngene output correct? Is my codes correct?
Thancks in advance
Tiziana

[Michiel Bliemer]

Ngene can only generate basic OOD designs considering only main effects, it does not consider interaction effects. The procedure for main effects is described in Appendix 6B of the Ngene manual. The fact that you used to get 24 rows is likely due to the fact that you generate a design using a more complex strategy that can handle interaction effects. It is also true that OOD designs can also generate duplicates.

Not many people use them and not many people use orthonormal coding when estimating their models, making their designs not efficient, so make sure that you are using orthonormal coding when you are estimating your model when using these designs. This can be tricky with interaction effects.

Michiel

[Tiziana]

Dear Michiel Bliemer, thank you for your reply.
Actually, I'm working on a design to carry out a pilot survey. Then, I'm going to use the estimates from the data of the pilot survey as priors to construct an efficient design. So, my questions are:1) If I perform a design using the codes below, can I then estimate a MNL also including the interaction term b4 NCL * NCS? Is this correct? In other words, can I use b4 as prior for the implementation of an efficient design?
Design
;alts = alt1, alt2
;rows = 8
;orth = ood
;model:
U(alt1) = b1 PR[0,1,2,3] + b2 NCL [0,1] + b3 NCS [0,1] + b4 NCL * NCS/
U(alt2) = b1 PR + b2 NCL + b3 NCS + b4 NCL * NCS
$

2) Is there any rule to set up the number of choice sets when we would like to estimate both main effects and interaction terms?

3) Given my attributes and the fact that I would also like to estimates b4 NCL * NCS is there any design that I can use for the pilot survey that can correctly account for main effects and 1 two way interaction?
Thank you in advance for your help.
Tiziana

[Michiel Bliemer]

I would suggest not using an OOD design, as they are not very flexible, and if you are not using orthonormal coding for your betas, they are not efficient.

I would suggest using the following syntax, which will create a design of 8 choice tasks that ensures that the interaction effect will work:

Code: Select all

Design
;alts = alt1, alt2
;rows = 8
;orth = seq
;eff = (mnl,d)
;model:
U(alt1) = b1 * PR[0,1,2,3] + b2 * NCL [0,1] + b3 * NCS [0,1] + b4 * NCL * NCS/
U(alt2) = b1 * PR + b2 * NCL + b3 * NCS + b4 * NCL * NCS
$

Alternatively, you can follow an orthogonal design and create the foldover, resulting in a design of 24 choice tasks in which every main effect is orthogonal with every interaction effect:

Code: Select all

Design
;alts = alt1, alt2
;rows = 8
;orth = sim
;foldover
;model:
U(alt1) = b1 * PR[0,1,2,3] + b2 * NCL [0,1] + b3 * NCS [0,1] /
U(alt2) = b1 * PR + b2 * NCL + b3 * NCS
$