choice-metrics.com

Dear NGENE Users

I have a query regarding a Bayesian efficient design that I am trying to generate. The study relates to preferences for weight loss treatments.

The query relates mainly to the status quo option. For all my attributes except for attribute C the levels are zero for the status quo option (so one of my attributes is chance of diabetes remission - which is 0 for the status quo). I do not want any of the status quo levels to appear as levels in the experimentally design alternatives so I leave this out of the design when generating the non-status quo alternatives. Attribute C is related to risk of heart disease, so for the status quo (which is do not participate in weight loss treatment) the risk of heart attack increases if the person does nothing – the other levels for this attribute relates to a reduction in this risk for the experimentally designed alternative.

So I am just wondering is the following syntax correct for this specification. I am assuming that when attributes are zero for the status quo or 30 in the case of Attribute C, I can leave them out of the utility function for the status quo alternatives. Reading the manual shows that there is a difference between no change and reference status quo (ours is a reference status quo) so I want to ensure my syntax is correct

Design

;alts = alt1*, alt2*, alt3*, alt4

;rows = 12

; con

;eff = (mnl,d, mean)

;model:

U(alt1) = b1[(n,0.2,0.1)] * A1[5,15,25] + b2[(n,0.3,0.15)] * B1[2,10,50] + b3[(n,0.4,0.2)] * C[5, 10, 15] + b4[(n,-0.07,0.03)] * D[5,25,50,70,100,125] + b5.dummy[(n, 0.4,0.2)] * E[0,1] + b6.dummy[(n,0.6,0.3)|(n,0.4,0.2)] * A[0,1,2] /

U(alt2) = b1[(n,0.2,0.1)] * A1[5,15,25] + b2[(n,0.3,0.15)] * B1[2,10,50] + b3[(n,0.4,0.2)] * C[5, 10, 15] + b4[(n,-0.07,0.03)] * D[5,25,50,70,100,125] + b5.dummy[(n, 0.4,0.2)] * E[0,1] + b6.dummy[(n,0.6,0.3)|(n,0.4,0.2)] * A[0,1,2] /

U(alt3) = b1[(n,0.2,0.1)] * A1[5,15,25] + b2[(n,0.3,0.15)] * B1[2,10,50] + b3[(n,0.4,0.2)] * C[5, 10, 15] + b4[(n,-0.07,0.03)] * D[5,25,50,70,100,125] + b5.dummy[(n, 0.4,0.2)] * E[0,1] + b6.dummy[(n,0.6,0.3)|(n,0.4,0.2)] * A[0,1,2] /

U(alt4) = b7[-0.001] $

Hi,

You can put the status quo level directly in the utility function, see below. I also added the Bayesian draw type. I made your prior values smaller, as they seem too large for the attribute levels, and Ngene will not be able to generate very good designs as you will have too many dominant alternatives in choice tasks. The priors have to be as realistic as possible, I just divided by 10 in order to be able to run it, but you probably want to set them more carefully.

Michiel


Design
;alts = alt1*, alt2*, alt3*, SQ
;rows = 12
;bdraws = gauss(3)
;con
;eff = (mnl,d, mean)
;model:
U(alt1) = b1[(n,0.02,0.01)] * A1[5,15,25] + b2[(n,0.03,0.015)] * B1[2,10,50] + b3[(n,0.04,0.02)] * C[5, 10, 15] + b4[(n,-0.007,0.003)] * D[5,25,50,70,100,125] + b5.dummy[(n, 0.04,0.02)] * E[0,1] + b6.dummy[(n,0.06,0.03)|(n,0.04,0.02)] * A[0,1,2] /
U(alt2) = b1 * A1 + b2 * B1 + b3 * C + b4 * D + b5 * E + b6 * A /
U(alt3) = b1 * A1 + b2 * B1 + b3 * C + b4 * D + b5 * E + b6 * A /
U(SQ) = b0[-0.001] + b3 * C2[30] $

Many thanks Michiel,
This is very helpful.