choice-metrics.com

Hello

I will run an unlabelled experiment with 3 treatments, 9 set per person:
1: attribute C and price
2: attribute H and price
3: attributes C and H and price

C and H are 3 level categorical variables (low, med , high)
People are randomly assigned to 1 treatment at random
It is a consequential lab experiment (not hypothetical) so samples will be small - c.80 per reatment

I want to see how the the value of C and H are affected when they appear alone versus with the other non-price attribute.

So I plan to estimate a pooled model, with treatment interactions.
I ran pilots with orthogonal designs so I have priors.

I would appreciate wisdom on the design(s) for the main study given the intention to pool the data and test for treatment effects.

eg should I:
A--Generate 3 different designs using priors from the 3 pilots
B--Generate a single design ( orthogonal / D eff zero priors) and remove the C and H attributes in the relevant treatments
C--Generate an efficient design from treatment 3 pilot and remove the C and H attributes in the relevant treatments
D-- other...

A has the advantage of efficient design (with a small sample) but risks any treatment effects being affected by the differences in design
B seems likely to avoid any design effect, at the cost of efficiency.
C is a hybrid!

One note - the priors for C and H are very similar - see below for the syntax used to generate an efficient design for T3

thanks
Dan

Code: Select all

Design
;alts = Alt1, Alt2, Alt3, None
;rows = 144
;block = 18
;eff = (mnl,s, mean)
;model:
U(Alt1) = h.dummy[ (n,1.2,0.6) | (n,0.6,0.3)]*h[0,1,2] + c.dummy [(n,1.8,0.6) | (n,0.8,0.3)]*c[0,1,2]+ pr[(n,-1.5,0.6) ]*p[2:6:0.5]   /
U(Alt2) = h.dummy*h[0,1,2] + c.dummy*c[0,1,2] + pr*p[2:6:0.5]   /
U(Alt3) = h.dummy*h[0,1,2] + c.dummy*c[0,1,2] + pr*p[2:6:0.5]   /
u(None) = n[n,(n,-3,0.3),(u,0.1,0.5)]*none[1]
$



I think you will have issues with each approach (A,B,C) if you are using 3 generic alternatives because one of the alternatives will be dominant, understanding that all attribute levels are decreasing in utility. So I think that you can only consider 2 generic alternatives.

Approach A would work, but as you say it loses statistical power when comparing treatments.

Approach B would work if you manually impose dominance constraints, see script below. There exist only 648 choice tasks without dominant alternatives after removing C or H.

Approach C could possibly make sense although after removing C or H the choice probabilities change and the design may no longer be efficient.

Code: Select all

Design
;alts = Alt1*, Alt2*, None
;rows = 144
;block = 18
;eff = (mnl,d)
;alg = mfederov(candidates = 648)
;reject:
Alt1.h <= Alt2.h and Alt1.p <= Alt2.p,
Alt1.h >= Alt2.h and Alt1.p >= Alt2.p,
Alt1.c <= Alt2.c and Alt1.p <= Alt2.p,
Alt1.c >= Alt2.c and Alt1.p >= Alt2.p
;model:
U(Alt1) = h.dummy[0.02|0.01]                                * h[0,1,2]
        + c.dummy[0.02|0.01]                                * c[0,1,2]
        + pr.dummy[0.08|0.07|0.06|0.05|0.04|0.03|0.02|0.01] * p[2,2.5,3,3.5,4,4.5,5,5.5,6]
        /
U(Alt2) = h                                                 * h
        + c                                                 * c
        + pr                                                * p
        /
U(None) = n[0]
$


When using uniformative near-zero priors, I generally consider dummy coded variables for all attributes as this provides a design with more variation, which is also beneficial when interested in interaction effects. Later in model estimation you can of course use a linear numerical effect for price.

Michiel

Thanks for this Michiel
You are right, there is/was a problem with dominated options using 3 generic Alts, esp with only one non-price attribute.
2 Alts makes much more sense

Thanks also for the suggestion re dummy coding all attributes when using uniformative near-zero priors.

Just be sure....is your syntax using that approach relating to my option B:

"Generate a single design ( orthogonal / D eff zero priors) and remove the C and H attributes in the relevant treatment"

thanks
Dan

Yes my script reflects your option B, where you simply omit one of the attributes, which does not affect efficiency when using uninformative priors.

Great, thank you

Dan