choice-metrics.com

Good day,

I want to generate an unlabeled design with 2 alternatives and a status quo option. Attribute D is the price attribute and I would like constraint it to > 0 for alt1 and alt2. The status quo option has specified levels which should be fixed/constant for all choice tasks.

I run the syntax below but the constraints were not obeyed. There were still 0 attribute levels in alt1 and alt2, and the sq option varied.

Question:

1. Is the syntax below correct?
2. Should I rather remove the status quo option in the model specification and introduce ASC in alt1 and alt2 (in the model specification). Which is better?

Code: Select all

Design;
;alts = alt1, alt2, sq
;rows = 12
;eff = (mnl,d,mean)

;bdraws = gauss(1)

;require:
alt1.D > 0,
alt2.D > 0,
sq.A = 0 and sq.B = 12 and sq.C = 2500 and sq.D = 0

;model:
U(alt1) = b2.dummy[(n,0.168138,0.085785)|(n,0.336276,0.085785)] * A[0,1,2] + b3[(n,0.028023,0.007149)] * B[8,12,16] + b4[(n,0.000028,0.114365)] * C[1000,2500,5000,7500] + b5[(n,-0.011209,0)] * D[0,10,20,40,80,120]/
U(alt2) = b2 * A + b3 * B + b4 * C + b5 * D /
U(sq) = b2 * A + b3 * B + b4 * C + b5 * D
$

Thank you in advance for your assistance.

Best regards,

Linda

Hi Linda

Please post Ngene syntax questions in the other forum in future - this forum is for general questions about designs.

There are a few problems with your syntax.

1. You have an additional ; in Design;
2. You have zero variance term for b5
3. There is a problem with b4[(n,0.000028,0.114365)] * C[1000,2500,5000,7500] the variance term is huge. Given this is a normal distribution which has bounds [-inf,+inf], the large variance with the large levels is producing very large utilities which is causing computation errors.
4. You don't need the constraints, you can use the same beta but define a different variable, with non-zeros for the non-SQ attributes.
5. Further, your SQ is like no other I have seen before. Normally you would have a single level for an SQ alternative (such as zero price, but also for the other variables). In your syntax, the SQ price for example will take on levels 0,10,20,40,80,120].

Ignoring 5. above, the syntax below works

Code: Select all

Design
;alts = alt1, alt2, sq
;rows = 12
;eff = (mnl,d,mean)
;bdraws = gauss(2)
;model:
U(alt1) = b2.dummy[(n,0.168138,0.085785)|(n,0.336276,0.085785)] * A[0,1,2] + b3[(n,0.028023,0.007149)] * B[8,12,16] + b4[(n,0.000028,0.00000114365)] * C[1000,2500,5000,7500] + b5[(n,-0.011209,0)] * D[10,20,40,80,120]/
U(alt2) = b2 * A + b3 * B + b4 * C + b5 * D /
U(sq) = b2 * A + b3 * B + b4 * C + b5 * D1[0,10,20,40,80,120] $


If price, should be zero for the SQ, then you can do this

Code: Select all

Design
;alts = alt1, alt2, sq
;rows = 12
;eff = (mnl,d,mean)
;bdraws = gauss(1)
;model:
U(alt1) = b2.dummy[(n,0.168138,0.085785)|(n,0.336276,0.085785)] * A[0,1,2] + b3[(n,0.028023,0.007149)] * B[8,12,16] + b4[(n,0.000028,0.00000114365)] * C[1000,2500,5000,7500] + b5[(n,-0.011209,0)] * D[10,20,40,80,120]/
U(alt2) = b2 * A + b3 * B + b4 * C + b5 * D /
U(sq) = b2 * A + b3 * B + b4 * C + b5 * D1[0] $


If you want to fix the levels of the other attributes, you can do that also, but please be careful. If you read the most recent posts, you will see doing this can cause issues with dummy codes.

John

Good day Prof,

Thank you so much for the detailed feedback.

Apologies for posting in the wrong forum.

Grateful,

Linda