choice-metrics.com

Hi Experts:

I am now trying homogeneous pivot design. I will have around 200 participants, around 50 are employed and 150 unemployed. Therefore, I have two segments, employed and unemployed. I have a reference for each group.The code is shown at the bottom.

1. Although all the attributes are continuous variables and can be considered having a linear relationship with utility function, I am wondering whether pivot design can accommodate non-linearity assumption? In tradition design, I can use 'dummy.attribute' to assume non linearity even though attribute is continuous variable. How should I do this in pivot design?

2. It seems pivot design does not allow 'condition' or 'requirement'. In my design, I want to set a condition: 'if alt2.A <alt1.A, then alt2.Price<alt1.Price'. Otherwise, there will be dominate choices. Any suggestion on this issue?

3. If pivot design can not solve the first and the second issue, I can return to the tradition design and have two separate designs, which I assume I can not analyse the two design together. Given my small sample size, I prefer combining two groups together. Or I just have one design, regardless the difference between employed and unemployed. In the analysis stage, I created a variable indicating employment status, and interactive this term with other attributes. But this design seems not very realistic, compared to pivot design.

4. Regarding the opt-out, I know pivot design can have two other alternatives around reference levels. I am thinking may I have three alternatives: reference alternative, new alternative, and participants' current status. If I have participants' current status, it seems setting reference alternative lost its meaning. To me, this design is similar to the tradition design, setting first alternative as reference, second as new alternative and third as status quo ('current status').

5. One minor question, in the paper Rose et al. (2008), participants were first asked to choice one among three alternatives, and then asked to make a choice among route A and B. From analytical perspective, how to analysis this data if the answer in 1st step is not consistent with the answer in 2nd step?

Sorry for asking so many questions. I am quite new to stated choice experiment and never use pivot before.

Thank you,

Connie

Code: Select all

Design
;alts(employed)=alt1,alt2,opt
;alts(unemployed)=alt1,alt2,opt
;rows=12
;eff=fish(mnl,d)
;fisher(fish)=design1(employed[0.2:0.3],unemployed[0.7:0.8])
;model(employed):
U(alt1)=b1*A.ref[25]      +b2*B.ref[10]    +b3*C.ref[5]     +b4*D.ref[15]    +b5*E.ref[1]     +b6*Price.ref[2700]/
U(alt2)=b1*A.piv[-10,0,10]+b2*B.piv[-5,0,5]+b3*C.piv[-5,-2,0,2]+b4*D.piv[-5,0,5]+b5*E.piv[-1,0,1]+b6*Price.piv[-500,0,500]

;model(unemployed):
U(alt1)=b1*A.ref[0]      +b2*B.ref[20]    +b3*C.ref[5]     +b4*D.ref[25]    +b5*E.ref[2]      +b6*Price.ref[1500]/
U(alt2)=b1*A.piv[15,25,35]+b2*B.piv[-10,-5,0]+b3*C.piv[-5,-2,0,2]+b4*D.piv[-10,-5,0]+b5*E.piv[-2,0,1]+b6*Price.piv[500,750,1000]

$



1. I suggest that you create a design with absolute levels and then convert it to a pivot design in the survey instrument. I converted your levels to the following absolute levels, and once you retrieve the design you can convert them back into pivots.

Code: Select all

? Employed
Design
;alts=ref,alt1,optout
;rows=12
;eff=(mnl,d)
;cond:
if(ref.Aref < alt1.A, ref.Priceref < alt1.Price)
;model:
U(ref)    = b1 * Aref[25]
          + b2 * Bref[10]
          + b3 * Cref[5]
          + b4 * Dref[15]
          + b5 * Eref[1]
          + b6[-0.000001] * Priceref[2700]
          /
U(alt1)   = b1 * A[15,25,35]
          + b2 * B[5,10,15]
          + b3 * C[0,3,5,7]
          + b4 * D[10,15,20]
          + b5 * E[0,1,2]
          + b6 * Price[2200,2700,3200]
          /
U(optout) = b0
$

Regarding dummy coding, e.g. b.dummy[0|0] * X[1,2,3], pivots work on the attribute levels so if the reference level is 2 then you can pivot -1 and +1 to levels 1 and 3. Clearly, if the reference level is 1, then you can only pivot +1 and +2. You will need to use logic in the survey instrument to do this kind of pivoting, or create a library of designs for different combinations of reference levels.

2. In the code above I have added the constraint. Usually dominant alternatives are avoided by using the sign of the priors and automatic dominance checks, e.g. ;alts = ref*, alt1*,optout.

3. You can generate two separate designs, one for employed and one for unemployed, and analyse the pooled data together in a single model. It is quite common to do this, also in revealed preference data where all attribute levels are different for all respondents and you combine all data. In the analysis stage you can indeed use the employment indicator to check for interactions and/or add the indicator as a main effect in the optout.

4. A reference alternative is a respondent-specific status quo alternative. You cannot have a reference alternative and a status quo alternative, they are the same. Possible ways to use three alternatives: (Ref, Alt1, Alt2), or (Ref, Alt1, Optout).

5. If the respondent selects Route A (or B) in the three-alternative choice set, then the respondent no longer needs to make a choice in the two-alternative choice set because Route A (or B) will be automatically selected in the survey instrument (maybe this was not explained in the paper). Only if the respondent selects the Reference alternative the respondent will be forced to make a second choice between A and B. Therefore, there is never any inconsistency in choice data.

Michiel

Thank you so much, Professor Michael, for always very helpful suggestions!

Greetings Michiel,
I ran into a similar issue as Connie in terms of needing to use conditions and required levels for a status quo alternative. I ran your recommended code and noticed that some of its outputs are odd, specifically the S estimate and the individual parameters being undefined, nor using the specified priors. Is this expected when using pre-specified alternatives? In my own design, rerunning with the reference alternative seemed to resolve some of these issues.
Appreciatively, Jerrod

Hi Jerrod,

In my example syntax I did not specify any priors so they are assumed zero, therefore S-estimates are undefined and meaningless (dividing by zero is not possible). If you have priors from a pilot study, you should use those priors and sample simze estimates will be meaningful, otherwise they should be ignored.

Michiel