Ordered labeled alternatives

[izakro]

Hi all,
We aim at designing SP choice tasks in order to investigate ultra-orthodox population's willingness to reduce consumption of singe-use plastics (which is consumed by them on a daily basis given high benefit-cost ratio). In the choice task we consider, the labeled alts. represent the level of reduction, e.g. (1) non-disposable use Sundays, (2) non-disposable use Sundays+Tues. and (3) non-disposable use Sundays+Tues+Thurs.
The atts. include the rate of participation in the community for each alt. and whether the religion authority (spiritual leader) supports the alt. etc.
I'm concerned about the fact that the labels of the alts. are ordered with (3)<<(2)<<(1). Is this consist a problem?
I can use instead a generic design but then I'll have too many atts.
Any hint?
Best
Rotem

[Michiel Bliemer]

If there is an ordering in the alternatives I believe that you need to use an ordered logit model. I am not an expert in that type of modelling so cannot advise you if you use ordered labels. You also need to randomise the order of labelled alternatives for each respondent in order to account for left-to-right bias.

Using unlabelled (generic) alternatives would solve both issues, there is no more ordering in alternatives and alternative orders do not need to be randomised. Instead of showing the level of reduction in the label, you would include the level of reduction as an additional attribute. If you think that there are too many attributes, you could always consider a partial profile design, see the Ngene manual.

Michiel

[izakro]

Thank you Michiel.
The labels are indeed ordered yet the attributes' level create trade-off (e.g. if the Rabbi supports the less preferred option, or if most of the community joined it, it gives the atts. positive weight). So I'll adhere with the labeled design. My other Q. is that despite endowing priors to the params. (based on past studies)
I receive 10% scenarios with strictly dominants (inferiors) alts. Any way I can avoid it? below is the syntax.
Design
;alts = Sunday, Sun_Tues, Sun_Tues_Turs, optout
;rows = 20
;block=5
;eff = (mnl,d)
;rdraws=halton(250)
;rep = 500
;model:
U(Sunday) =b1[-0.3]+ b2[n,0.4,0.2]*participation[ 1,2,3] + b3[n,0.2,0.19]* reduced_eco_risk[1,2,3]+b4[n,0.6, 0.01]*rabbi_support[1,3,5]/
U(Sun_Tues)=c1[-0.6]+ b2 *participation+b3* reduced_eco_risk+ b4*rabbi_support/
U(Sun_Tues_Turs)= d1[-0.9]+b2 * participation+b3* reduced_eco_risk+ b4*rabbi_support$

[Michiel Bliemer]

You can check for dominant alternatives by using an asterisk behind the names of alternatives, i.e. ;alts = Sunday*, Sun_Tues*, Sun_Tues-Turs*, Optout
However, strictly, dominant alternatives are only defined for unlabelled alternatives, but may work in your case. When you add this to your syntax, you will see that Ngene can no longer find a design without any dominant alternatives using the default algorithm. You will then need to switch to the modified Federov algorithm and possibly include attribute level constraints.

You have specified a mixed logit model with fixed priors, not a multinomial logit model with Bayesian priors. I assume that this is what you want?

I am not sure whether participation levels 1,2,3 and eco risk 1,2,3 makes sense, do you put values 1,2,3 directly into your data for estimating models? One would typically use dummy coding for categorical variables, e.g. b2.dummy[..|..] * participation[1,2,3], where level 3 is the reference level.

Michiel

[izakro]

Thanks a million for your help
Yes, for some atts. the levels should have been dummy coded (the risk for example is "low" "med" and "High") but for participation I would like to use the real levels (20%, 50%, 80%) yet I wasn't sure whether to use [20, 80,50] or [0.2, 0.5, 0.8]
My design had ;eff = (mnl,d), isn't it a multi-nominal logit one? and I believe I should use bdraws rather than rdraws for a Bayesian desgin
I have run the following design (compensation is in monetary amount granted per months, and to whom- a categorical var.; who receives the compensation: the Rabbi, respondent's kids, or the respondent.
There was no dominant alternative, and the s estimate is reasonable. Yet, looking at the choice probabilities, the optout option is never chosen. Is that a problem?
Design
;alts = Sunday*, Sun_Tues*, Sun_Tues_Turs*, optout
;rows = 20
;block=5
;eff = (mnl,d)
;bdraws=halton(250)
;alg = mfederov
;rep = 500
;model:
U(Sunday) =b1[-0.3]+ b2[n,0.4,0.2]*participation[ 0.2,0.5,0.8] + b3.dummy[n,-0.2,0.05|n,-0.15,0.01]* risk[1,2,3]+b4[n,0.6, 0.01]*compensation[1,3,5]+b5.dummy[n, -0.2, 0.05|n, -0.15,0.01]* to_whom[1,2,3]/
U(Sun_Tues)=c1[-0.6]+ b2 *participation+b3* risk+ b4*compensation+ b5*to_whom/
U(Sun_Tues_Turs)= d1[-0.9]+b2 * participation+b3* risk+ b4*compensation+ b5*to_whom $

[Michiel Bliemer]

You need you use round brackets around Bayesian priors, see syntax below.
Further, you may want to impose attribute level constraints as I did for non-dummy coded variables when using the modified Federov algorithm, see below.
Also, I recommend using Gaussian quadrature with 3 abscissas, see below.
Finally, the last level (3) is the reference level for dummy codind and the coefficients for levels 1 and 2 should be relative to this reference level.

Code: Select all

Design
;alts = Sunday*, Sun_Tues*, Sun_Tues_Turs*, optout
;rows = 20
;block=5
;eff = (mnl,d)
;bdraws=gauss(3)
;alg = mfederov
;model:
U(Sunday)        = b1[-0.3]
                 + b2[(n,0.4,0.2)]                        * participation[0.2,0.5,0.8](5-9,5-9,5-9)
                 + b3.dummy[(n,-0.2,0.05)|(n,-0.15,0.01)] * risk[1,2,3]  ? 1 = ..., 2 = ..., 3 = ... (reference level)
                 + b4[(n,0.6,0.01)]                       * compensation[1,3,5](5-9,5-9,5-9)
                 + b5.dummy[(n,-0.2,0.05)|(n,-0.15,0.01)] * to_whom[1,2,3] ? 1 = ..., 2 = ..., 3 = ... (reference level)
                 /
U(Sun_Tues)      = c1[-0.6]
                 + b2 * participation
                 + b3 * risk
                 + b4 * compensation
                 + b5 * to_whom
                 /
U(Sun_Tues_Turs) = d1[-0.9]
                 + b2 * participation
                 + b3 * risk
                 + b4 * compensation
                 + b5 *to_whom
$

The choice probabilities depend on the priors that you have set, so if the choice probabilties do not look good then that is because your priors are not appropriate (your constants have a large influence on this). Priors typically come from a pilot study, and if setting manually should be done with great care or should be set (very close to) zero.

Michiel

[izakro]

Thank you so so much! it is well understood. Just to make sure about the dummy coding. Our risk[1,2,3] att is actually risk reduction and it is ordered so that level 3 is the most preferred. In that case, does assigning negative prior values to levels 1 and 2 (e.g. -0.2|-0.15) makes sense?
and this time really finally, is there any criterion to determine the number of desired repetitions of a level in the design (5-9 in the example provided)?

[Michiel Bliemer]

1. Yes with negative dummy coded parameter priors you indicate the ordering of the levels where level 1 is least preferred and level 3 is most preferred.
2. Attribute level balance is not a requirement, but usually one would like each level to appear a certain amount. If you do not impose any constraints, the middle level may not appear at all.

Michiel

[izakro]

Thanks a million for your help!