DCE with status quo and dominant alternatives

[Michiel Bliemer]

Yes I would increase the number of rows to increase diversity in the data, which also means increasing the number of blocks.

If you change the number of rows, you indeed also need to update level constraints such as (5,5,4).If you have ;rows = 27 and ;block = 3 then you can use a range such as (8-10,8-10,8-10), while if you have ;rows = 21 and ;block = 3 then you can use a range such as (6-8,6-8,6-8). Using a range makes it much easier to optimise the design. The wider the range, the more efficient the design, but the less attribute level balance.

Michiel

[JvB]

So, according to S>K/(J-1) there is a minimum of 4 choice tasks that need to be presented. As derived from the literature to have more variety I would take 3*4=12 and multiply it by 2 because for MMNL I have to estimate the double amount of parameters. Is that a resonable approach? Or can I, if I want to present for example 7 tasks just choose any number of rows that is divisible by 7? I am a bit insecure, as I did not find any clear statement on this, so could also choose 70 rows (7 tasks, 10 blocks) because more rows mean more variety which is always better?!

And how can I test my design (which is optimised for MNL) how it performs with MMNL?

Design
;alts = alt1*, alt2*, SQ*
;rows = 24
;block = 3
;eff = (mnl,d)
;alg = mfederov
;require:
SQ.amount = 3, SQ.period = 3
;reject:
alt1.amount = 3 AND alt1.period = 3,
alt2.amount = 3 AND alt2.period = 3
;model:
U(alt1) = b1[-0.4862] * contrib[1.8,3.3,4.8](7-9,7-9,7-9)
+ b2.dummy[1.4049|1.0240|0.4527] * amount[0,1,2,3] ? 0 = 300, 1 = 600, 2 = 900, 3 = unlimited amount
+ b3.dummy[1.0609|0.5951|0.2733] * period[0,1,2,3] ? 0 = 12, 1 = 42, 2 = 72, 3 = unlimited period
/
U(alt2) = b1 * contrib
+ b2 * amount
+ b3 * period
/
U(SQ) = b0[-0.9618]
+ b1 * contrib_sq[1.6]
+ b2 * amount
+ b3 * period
$

Thank you very much for your support!

[Michiel Bliemer]

You have 8 parameters and 3 alternatives, so that you need a minimum of 8/2 = 4 rows in your design. That is the theoretical minimum. However, there is not much variation in 4 rows, so my rule of thumb is that you need at least 3 times the theoretical minimum, in your case 3*12 = 12. But you can always increase this number for more variation in the data, that is never a bad thing. In choosing the number of rows, you would indeed look at how many choicetask you would like to give to your respondents. If you would like to give 7 choice tasks, then indeed you want the number of rows to be divisible by 7, so you would choose 14, or 21, etc. Also 70 is fine, but there is likely no need to use such a large design.

Michiel

[JvB]

Thank you very much!
I´ve now tried some different options and decided for the following design:

Design
;alts = alt1*, alt2*, SQ*
;rows = 42
;block = 6
;eff = (mnl,d)
;alg = mfederov
;require:
SQ.amount = 3, SQ.period = 3
;reject:
alt1.amount = 3 AND alt1.period = 3,
alt2.amount = 3 AND alt2.period = 3
;model:
U(alt1) = b1[-0.4862] * contrib[1.8,3.3,4.8](13-15,13-15,13-15)
+ b2.dummy[1.4049|1.0240|0.4527] * amount[0,1,2,3] ? 0 = 300, 1 = 600, 2 = 900, 3 = unlimited amount
+ b3.dummy[1.0609|0.5951|0.2733] * period[0,1,2,3] ? 0 = 12, 1 = 42, 2 = 72, 3 = unlimited period
/
U(alt2) = b1 * contrib
+ b2 * amount
+ b3 * period
/
U(SQ) = b0[-0.9618]
+ b1 * contrib_sq[1.6]
+ b2 * amount
+ b3 * period
$
______

I might want to estimate interactions with the data of the main survey (besides standard main effects and interactions with socio-demographic data). As I have some reject and require in my design is it even possible to estimate interactions and is there anything special to take into account/to look at in the output file of the design to make sure that interactions can be estimated? I´ve tried to interpret the correlations_interactions output but did not really know how to interpret it. There are quite lots of "!" and "." in the table which might be due to restirctions that I´ve put to the syntax (reject, require)?

[Michiel Bliemer]

You can interact sociodemographics with any of the attributes as long as their levels vary. The status quo alternative has fixed levels, which is wly the correlation coefficient is not defined for interactions with the status quo attribute levels ("!" in the correlation matrix), but it would be fine to create interactions such as income*contrib, or gender*amount.dummy[1], etc. Note that interactions with dummy variables need to be made with specific levels.

Michiel

[JvB]

Thank you very much for clarification, Michiel.
According to my understanding it is then not necessary to put any possible interactions to the design syntax in NGENE but to leave it as basic as it is for optimization, isnt´it?

[Michiel Bliemer]

Correct, it is not possible to include interactions with sociodemographics in the utility function at the design stage because these sociodemographics are unknown. It is of course possible to create separate designs for different segments of the population, e.g. a design for men and a design for women, and for this purpose the .covar suffix is available in Ngene, see Section 8.4 of the manual. But this feature is hardly ever used and is only really of interest if different segments have very different behaviour.

Michiel

[JvB]

Probably and hopefully, this will be the last quick question on design output in this thread:
I have, with my priors from pretest (N=42) a B-estimate of 53. In the literature it says, that 70-90 would be an efficient design. Is that anything to worry about?

[Michiel Bliemer]

The 70-90 range is a value that I found for 2 alternatives, I do not think there is a range for 3 alternatives. Note that you have a status quo alternative with fixed levels, so utility balance is difficult to change for this alternative and therefore utility balance will be lower when a status quo alternative is present.

To be honest, I never look at the B-estimate and in the new version we will likely omit this measure as it is not very informative. Your B-estimate looks fine, I would mainly worry if it is something like 0.1 or lower, which would mean a lot of weakly dominant alternatives.

Michiel

[JvB]

Thank you very much, Michiel!