little information in genereated scenario's

[Louise]

Dear NGene users,

In my design I have two alternatives (2 new types of bio-based fertiliser A and B) and a current artificial fertilizer use as status quo.
When I generate the scenario's I have for example the option with only levels 0 in alt 1 (in an other scenario alt2 has only levels 0):

alt1 alt2
a 0 2
b 0 1
c 0 3
d 0 0
e 0 0
f 0 0
h 0 1
Choice question:

The problem is that this differs only very little from the current option. Will this give me enough information or can I introduce syntax to overcome this? I heard something about rseed, but I dont understand how this can help or how I should implement that?

My code:

Design
;alts=alt1,alt2, alt3
;rows=13
;orth=seq
;eff = (mnl, d)
;block=2
;model:
U(alt1)=b2[0]*A[0,1,2,3]
+ b3[0|0|0].effects*B[0,1,2,3]
+ b4[0]*C[0,1,2,3]
+ b5[0].effects*D[0,1]
+ b6[0].effects* E[0,1]
+ b7[0].effects* F[0,1]
+ b8[0].effects*H[0,1] /
U(alt2)=b2*A+b3*B+ b4* C+b5 *D+ b6* E+ b7*F+ b8* H/
U(alt3)=b1[0]$

Does anyone have an idea? Thank you very much for your help!

Louise

[Louise]

Hello,

As what I understand from other forum questions and from the manual I could use cond; or reject; ? But this works for rows and I want to excluse all zero levels in the alternatives (this within one column)?

I there a way to exlclude a combination of attribute levels within one alternative?

Thank you in advance.

Louise

[Michiel Bliemer]

I believe the problem is in your specification of alt3. You only included a constant, so it cannot tell that 0,0,0,0,0 in alt1 is actually very simular to alt3. I do not know your study well, but why not formulating alt3 as a true status quo alternative? it is now formulated as a no-choice option without any attributes. i assume the status quo has some attributes as well (which are fixed)?

For example,
U(alt3) = b1[0]+b2*Asq[0]+b3*Bsq[0]+ b4* Csq[0]+b5 *Dsq[0]+ b6* Esq[0]+ b7*Fsq[0]+ b8* Hsq[0]

This way, you are telling Ngene that alt3 has the same attributes, but a specific value, and provides information on b2...b8 as well.

Or alternatively, you can include something like
;require:
alt3.A = 0, etc.
U(alt3)= b1[0]+b2*A+b3*B+ b4* C+b5 *D+ b6* E+ b7*F+ b8* H

The first option would be preferred as it avoids using constraints.

Would something that like work in your case?

Michiel

[Louise]

Dear Michiel,

The first option you gave looks more elegant indeed, but how will that increase the complexity of the design? Will this add to the rows needed?

The experiment will be used to estimate the acceptance of farmers towards new bio-based organic fertilisers as substitution of the current chemical fertilisers. Alt1 and alt2 are new types of bio-based fertilizers that do not exist yet. Alt3 it the current, chemical fertilizer used. Although chemical and bio-based, the attributes of both types are the same, but for 2 attributes I do not know the level of alt3. That is why I wanted to call alt3 'current fertilizer use', withouth specifying the levels. Nevertheless, in most cases the levels of alt3 will be 0, as such I wanted to avoid all levels to be 0 in for alt1 and alt2.

In theory I could make it a pivoting survey I guess, but the survey will be done in different European countries, some will be done online, others on hard copy, as a result a changing design is not possible.

Would you have any suggestion how to solve this problem?

Thank you very much in advance.

Louise

[Michiel Bliemer]

Have you tried my suggestion? It is the only correct way of adding a status quo alternative.
This should indeed avoid all zeros in the other alternatives, as with my proposed syntax you specifically state that b2, b3 etc are also part of the status quo, and efficient designs will try to make trade-offs in the attribute levels (otherwise it does not provide information). So if the status quo is a zero, then more information is obtained if at least one of the other attributes is not zero.

I would make some changes to your syntax though, as orthogonal arrays do not work with constraints or status quo alternatives like that. Also, I wonder why you have 13 rows, blocking this in 2 is problematic, so I changed it to 12. Try the syntax below.

Code: Select all

Design
;alts=alt1,alt2, alt3
;rows=12
;eff = (mnl, d)
;alg=mfederov(candidates=100)
;block=2
;require:
alt3.A=0, alt3.B=0, alt3.C=0, alt3.D=0, alt3.E=0, alt3.F=0, alt3.H=0
;model:
U(alt1)=b2[0]*A[0,1,2,3]
+ b3[0|0|0].effects*B[0,1,2,3]
+ b4[0]*C[0,1,2,3]
+ b5[0].effects*D[0,1]
+ b6[0].effects* E[0,1]
+ b7[0].effects* F[0,1]
+ b8[0].effects*H[0,1] /
U(alt2)=b2*A+b3*B+ b4* C+b5 *D+ b6* E+ b7*F+ b8* H/
U(alt3)=b1[0] + b2*A+b3*B+ b4* C+b5 *D+ b6* E+ b7*F+ b8* H
$


[Michiel Bliemer]

In reply to your other point, I am not sure what it means that you do not know the levels of certain attributes for your status quo... If you don't know, how are your respondents supposed to know? Or do these attributes not appear in the status quo? Then you can just remove those attributes from the status quo. If the status quo has attributes that are different from the others, you can simply add them, but adding a b10*K[3] will yield a constant, so all attributes that the status quo has and do not appear in the other alternatives will in the end go into the constant b1[0].

On another note, I notice you have not put any priors in your design. You do not even know the sign of the priors? I assume this is for an initial pilot study in which you have no idea about the parameter priors.

[Louise]

Dear Michiel,

When I try your suggestion it works indeed, thank you very much.

This is indeed my first version that I have to test in a pilot study. Of some attributes I know the sign, I added uniform Bayesian priors.

The reason why I don't know the attribute level for some attributes of the status quo is because it can differ for various respondents. Because some questionnaires will be done by post (hard copy, depending on the country) I cannot change the levels depending on the respondent. However, as a solution I would suggest that I indeed request all alt3 attribute levels to be zero. The respondents will not see the levels since the alt3 will be named 'current artificial fertiliser'.
Do think this is a good solution?

Alsoo, in my previous code (which was an orthogonal one) I started with 14 rows (in my posted code I made a mistake writing 13), which switched to 16 rows during running. You suggested I only need 12 rows? Don't I have to take into account the degrees of freedom (A*(L-1)+1=14), can I really only retain 12 or 14 rows in stead of 16?

Thank you very much.

Code: Select all

Design
;alts=alt1,alt2, alt3
;rows=14
;eff = (mnl, d)
;alg=mfederov(candidates=100)
;block=2
;require:
alt3.A=0, alt3.B=0, alt3.C=0, alt3.D=0, alt3.E=0, alt3.F=0, alt3.G=0
;model:
U(alt1)=b2[(u,-1,0)]*A[0,1,2,3]
+ b3[0|0|0].effects*B[0,1,2,3]
+ b4[(u,-1,0)]*C[0,1,2,3]
+ b5[0].effects*D[0,1]
+ b6[0].effects* E[0,1]
+ b7[0].effects* F[0,1]
+ b8[(u,-1,0)].effects*G[0,1]/
U(alt2)=b2*A+b3*B+ b4* C+b5 *D+ b6* E+ b7*F+ b8* G/
U(alt3)=b1[0]+ b2*A+b3*B+ b4* C+b5 *D+ b6* E+ b7*F+ b8* G $


[Michiel Bliemer]

I think for an initial study this should work. In pen and paper a status quo is indeed a bit trickier. The only way to overcome it is to make different versions. After selecting the fertiliser they use, you can direct them to a certain page of the survey that are specifically designed for that fertiliser. This of course will increase the number of pages needed to be send out significantly.

The degrees of freedom calculation you are using is not correct, we describe the correct calculation of the degrees of freedom in our more recent papers. This new calculation has been implemented in Ngene some time ago. Your code works fine and D-errors can be calculated with 14 rows, which is also a sign that the degrees of freedom are satisfied. \

The degrees of freedom are simply the number of parameters to estimate. In your syntax K = 10, if everything is effects coded, K = 14.
The number of datapoints is S*(J-1), where S is the number of choice tasks, and J is the number of alternatives. Since you have 3 alternatives, you actually get two datapoints per question (if the respondent selects alt1, then we know that alt1 is preferred over alt2, AND alt1 is preferred over alt3).

So the following needs to hold:

S*(J-1) >= K

where S is the number of rows, J is the number of alternatives, and K is the number of parameters to be estimated.

With K = 14 and J = 3, even S = 7 rows would be sufficient, so 12 rows is fine. If you only had 2 alternatives, 14 rows would be needed.